sci-chemistry/eden/eden-5.3-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit eutils multilib python-r1 toolchain-funcs
   9
  10 MY_P="${PN}_V${PV}"
  11
  12 DESCRIPTION="A crystallographic real-space electron-density refinement and optimization program"
  13 HOMEPAGE="http://www.gromacs.org/pipermail/eden-users/"
  14 SRC_URI="mirror://gentoo/${MY_P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="amd64 x86"
  19 IUSE="double-precision"
  20
  21 RDEPEND="
  22         sci-libs/fftw:2.1
  23         sci-libs/gsl"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig"
  26
  27 S="${WORKDIR}/${PN}"
  28
  29 SRC="${S}/source"
  30
  31 pkg_setup() {
  32         export EDENHOME="${EPREFIX}/usr/$(get_libdir)/${PN}"
  33 }
  34
  35 src_prepare() {
  36         epatch \
  37                 "${FILESDIR}"/${PV}-makefile-fixes.patch \
  38                 "${FILESDIR}"/${P}-impl-dec.patch \
  39                 "${FILESDIR}"/${P}-format-security.patch
  40
  41         sed -i \
  42                 -e "s:^\(FFTW.*=\).*:\1 ${EPREFIX}/usr:g" \
  43                 -e "s:^\(LIB.*=.*\$(FFTW)/\).*:\1$(get_libdir):g" \
  44                 -e "s:^\(BIN.*=\).*:\1 ${D}usr/bin:g" \
  45                 -e "s:^\(CFLAGS.*=\).*:\1 ${CFLAGS}:g" \
  46                 -e "s:-lgsl -lgslcblas:$($(tc-getPKG_CONFIG) --libs gsl):g" \
  47                 ${SRC}/Makefile || die
  48
  49         if ! use double-precision; then
  50                 sed -i -e "s:^\(DOUBLESWITCH.*=\).*:\1 OFF:g" ${SRC}/Makefile || die
  51                 EDEN_EXE="s${PN}"
  52         else
  53                 EDEN_EXE="d${PN}"
  54         fi
  55 }
  56
  57 src_compile() {
  58         emake CC=$(tc-getCC) -C ${SRC}
  59 }
  60
  61 src_install() {
  62         emake -C ${SRC} install
  63
  64         python_foreach_impl python_newscript python/${PN}.py i${PN}
  65         python_foreach_impl python_domodule python/FileListDialog.py
  66
  67         rm python/*py || die
  68         insinto ${EDENHOME}/python
  69         doins python/*
  70
  71         insinto ${EDENHOME}/help
  72         doins help/*
  73
  74         insinto ${EDENHOME}/tools
  75         doins tools/*
  76
  77         dodoc manual/UserManual.pdf
  78
  79         cat >> "${T}"/60${PN} <<- EOF
  80         EDENHOME="${EDENHOME}"
  81         EOF
  82
  83         doenvd "${T}"/60${PN}
  84
  85         dosym ${EDEN_EXE} /usr/bin/${PN}
  86 }