sci-biology/stride/stride-20011129-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils toolchain-funcs
   8
   9 DESCRIPTION="Protein secondary structure assignment from atomic coordinates"
  10 HOMEPAGE="http://webclu.bio.wzw.tum.de/stride/"
  11 SRC_URI="
  12         ftp://ftp.ebi.ac.uk/pub/software/unix/${PN}/src/${PN}.tar.gz
  13         https://dev.gentoo.org/~jlec/distfiles/${PN}-20060723-update.patch.bz2"
  14
  15 SLOT="0"
  16 LICENSE="STRIDE"
  17 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~x86-macos"
  18 IUSE=""
  19
  20 S="${WORKDIR}"
  21
  22 RESTRICT="mirror bindist"
  23
  24 src_prepare() {
  25         # this patch updates the source to the most recent
  26         # version which was kindly provided by the author
  27         epatch \
  28                 "${DISTDIR}/${PN}-20060723-update.patch.bz2" \
  29                 "${FILESDIR}"/${PN}-LDFLAGS.patch
  30
  31         # fix makefile
  32         sed -e "/^CC/s|gcc -g|$(tc-getCC) ${CFLAGS}|" -i Makefile || \
  33                 die "Failed to fix Makefile"
  34 }
  35
  36 src_install() {
  37         dobin ${PN}
  38 }