sci-biology/seaview/seaview-4.5.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils multilib toolchain-funcs
   7
   8 DESCRIPTION="A graphical multiple sequence alignment editor"
   9 HOMEPAGE="http://pbil.univ-lyon1.fr/software/seaview.html"
  10 SRC_URI="ftp://pbil.univ-lyon1.fr/pub/mol_phylogeny/seaview/archive/${PN}_${PV}.tar.gz"
  11
  12 LICENSE="public-domain"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE="+xft"
  16
  17 CDEPEND="
  18         sys-libs/zlib
  19         x11-libs/fltk:1
  20         x11-libs/libX11
  21         xft? (
  22                 x11-libs/libXft
  23                 x11-libs/fltk:1[xft] )"
  24 RDEPEND="${CDEPEND}
  25         sci-biology/clustalw
  26         || ( sci-libs/libmuscle sci-biology/muscle )
  27         sci-biology/phyml"
  28 DEPEND="${CDEPEND}
  29         virtual/pkgconfig"
  30
  31 S="${WORKDIR}/${PN}"
  32
  33 src_prepare() {
  34         # respect CXXFLAGS (package uses them as CFLAGS)
  35         sed \
  36                 -e "s:^CC.*:CC = $(tc-getCC):" \
  37                 -e "s:^CXX.*:CXX = $(tc-getCXX):" \
  38                 -e "s:\$(OPT):${CXXFLAGS}:" \
  39                 -e "s:^OPT:#OPT:" \
  40                 -e "s:^FLTK = .*$:FLTK = ${EPREFIX}/usr/include/fltk-1:" \
  41                 -e "s:^#IFLTK .*:IFLTK = $(fltk-config --use-images --cflags):" \
  42                 -e "s:^#LFLTK .*:LFLTK = $(fltk-config --use-images --ldflags):" \
  43                 -e "s:^USE_XFT:#USE_XFT:" \
  44                 -e "s:^#HELPFILE:HELPFILE:" \
  45                 -e "s:/usr/share/doc/seaview/seaview.htm:${EPREFIX}/usr/share/seaview/seaview.htm:" \
  46                 -e "s:^#PHYMLNAME:PHYMLNAME:" \
  47                 -e 's:-lXinerama::g' \
  48                 -e 's:-lpng::g' \
  49                 -e 's:-ljpeg::g' \
  50                 -e 's:-lfontconfig::g' \
  51                 -i Makefile || die "sed failed while editing Makefile"
  52
  53         if use xft; then
  54                 sed \
  55                         -e "s:^#USE_XFT .*:USE_XFT = -DUSE_XFT $($(tc-getPKG_CONFIG) --cflags xft):" \
  56                         -e "s:-lXft:$($(tc-getPKG_CONFIG) --libs xft):" \
  57                         -i Makefile || die "sed failed while editing Makefile to enable xft"
  58         else
  59                 sed -i -e "s:-lXft::" Makefile || die
  60         fi
  61 }
  62
  63 src_install() {
  64         dobin seaview
  65
  66         # /usr/share/seaview/seaview.html is hardcoded in the binary, see Makefile
  67         insinto /usr/share/seaview
  68         doins example.nxs seaview.html
  69
  70         insinto /usr/share/seaview/images
  71         doins seaview.xpm
  72
  73         make_desktop_entry seaview Seaview
  74
  75         doman seaview.1
  76 }