sci-biology/phylip/phylip-3.696-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION=" The PHYLogeny Inference Package"
   9 HOMEPAGE="http://evolution.genetics.washington.edu/phylip.html"
  10 SRC_URI="http://evolution.gs.washington.edu/${PN}/download/${P}.tar.gz"
  11
  12 SLOT="0"
  13 LICENSE="BSD-2"
  14 IUSE=""
  15 KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
  16 # 'mix' tool collides with dev-lang/elixir, bug #537514
  17 RDEPEND="x11-libs/libXaw
  18         !!dev-lang/elixir"
  19 DEPEND="${RDEPEND}
  20         x11-base/xorg-proto"
  21
  22 S="${WORKDIR}/${P}/src"
  23
  24 src_prepare() {
  25         mv Makefile.unx Makefile || die
  26         sed \
  27                 -e "/ -o /s:\(\$(CC)\):\1 ${LDFLAGS}:g" \
  28                 -i Makefile || die "Patching Makefile failed."
  29         mkdir ../fonts || die
  30 }
  31
  32 src_compile() {
  33         emake -j1 \
  34                 CC="$(tc-getCC)" \
  35                 DC="$(tc-getCC)" \
  36                 CFLAGS="${CFLAGS} -Wno-unused-result" \
  37                 all put
  38 }
  39
  40 src_install() {
  41         cd "${WORKDIR}/${P}" || die
  42
  43         mv exe/font* fonts || die "Font move failed."
  44         mv exe/factor exe/factor-${PN} || die "Renaming factor failed."
  45
  46         dolib.so exe/*so && rm exe/*so
  47         dobin exe/*
  48
  49         dodoc "${FILESDIR}"/README.Gentoo
  50
  51         dohtml -r phylip.html doc
  52
  53         insinto /usr/share/${PN}/
  54         doins -r fonts
  55 }