sci-biology/biopython/biopython-1.68.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 python3_5 pypy )
   7
   8 inherit distutils-r1 eutils
   9
  10 DESCRIPTION="Python modules for computational molecular biology"
  11 HOMEPAGE="http://www.biopython.org/ https://pypi.org/project/biopython/"
  12 SRC_URI="http://www.biopython.org/DIST/${P}.tar.gz"
  13
  14 LICENSE="HPND"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
  17 IUSE=""
  18
  19 RDEPEND="
  20         dev-python/matplotlib[$(python_gen_usedep 'python*')]
  21         dev-python/networkx[$(python_gen_usedep 'python*')]
  22         dev-python/numpy[$(python_gen_usedep 'python*')]
  23         dev-python/rdflib[$(python_gen_usedep 'python*')]
  24         dev-python/pygraphviz[$(python_gen_usedep 'python2*')]
  25         dev-python/reportlab[$(python_gen_usedep 'python*')]
  26         dev-python/pydot[$(python_gen_usedep 'python2*')]
  27         "
  28 DEPEND="${RDEPEND}
  29         sys-devel/flex"
  30
  31 DOCS=( CONTRIB DEPRECATED NEWS README Doc/. )
  32
  33 python_test() {
  34         distutils_install_for_testing
  35         cp -r "${S}"/{Doc,Tests} "${TEST_DIR}"/lib/ || die
  36         cd "${TEST_DIR}"/lib/Tests || die
  37         rm test_BioSQL_{psycopg2.py,MySQLdb.py,mysql_connector.py} || die
  38         ${PYTHON} run_tests.py --offline --verbose || die
  39 }
  40
  41 python_install_all() {
  42         distutils-r1_python_install_all
  43
  44         dodir /usr/share/${PN}
  45         cp -r --preserve=mode Scripts Tests "${ED%/}"/usr/share/${PN} || die
  46 }
  47
  48 pkg_postinst() {
  49         elog "For database support you need to install:"
  50         optfeature "MySQL" dev-python/mysql-python
  51         optfeature "PostGreSQL" dev-python/psycopg
  52         elog
  53         elog "Some applications need extra packages:"
  54         optfeature "EMBOSS (The European Molecular Biology Open Software Suite)" sci-biology/emboss
  55 }