sci-biology/biogrep/biogrep-1.0-r2.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Multithreaded tool for matching large sets of patterns against biosequence DBs"
   9 HOMEPAGE="http://stephanopoulos.openwetware.org/BIOGREP.html"
  10 SRC_URI="http://www.openwetware.org/images/3/3d/${P^}.tar.gz -> ${P}.tar.gz
  11         doc? ( http://www.openwetware.org/images/4/49/${PN^}.pdf -> ${P}.pdf )"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc examples"
  17
  18 src_prepare() {
  19         default
  20         mv configure.{in,ac} || die
  21         eautoreconf
  22 }
  23
  24 src_install() {
  25         use doc && DOCS+=( "${DISTDIR}"/${P}.pdf )
  26         if use examples; then
  27                 # remove cruft before installing examples
  28                 find examples/ \( -name 'CVS' -o -name '*~' \) -exec rm -rf '{}' + || die
  29
  30                 DOCS+=( examples )
  31                 docompress -x /usr/share/doc/${PF}/examples
  32         fi
  33
  34         default
  35 }