sci-biology/amos/amos-3.1.0-r4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit autotools flag-o-matic python-single-r1
   9
  10 DESCRIPTION="A Modular, Open-Source whole genome assembler"
  11 HOMEPAGE="http://amos.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
  13         https://dev.gentoo.org/~soap/distfiles/${PN}-3.1.0-fix-c++14.patch.bz2"
  14
  15 LICENSE="Artistic"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE=""
  19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  20
  21 DEPEND=""
  22 RDEPEND="${DEPEND}
  23         ${PYTHON_DEPS}
  24         dev-perl/DBI
  25         dev-perl/Statistics-Descriptive
  26         sci-biology/mummer"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${P}-gcc-4.7.patch
  30         "${FILESDIR}"/${P}-goBambus2.py-indent-and-cleanup.patch
  31         "${WORKDIR}"/${P}-fix-c++14.patch
  32         "${FILESDIR}"/${P}-qa-Wformat.patch
  33         "${FILESDIR}"/${P}-fix-build-system.patch
  34 )
  35
  36 src_prepare() {
  37         default
  38         eautoreconf
  39
  40         # prevent GCC 6 log pollution due
  41         # to hash_map deprecation in C++11
  42         append-cxxflags -Wno-cpp
  43 }
  44
  45 src_configure() {
  46         econf --with-qmake-qt4=no
  47 }
  48
  49 src_install() {
  50         default
  51         python_fix_shebang "${ED%/}"/usr/bin/goBambus2
  52 }