sci-astronomy/gnuastro/gnuastro-0.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils autotools ltprune
   7
   8 DESCRIPTION="GNU Astronomy Utilities"
   9 HOMEPAGE="https://www.gnu.org/software/gnuastro"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0/1"
  14 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  15
  16 IUSE="static-libs threads"
  17
  18 # jpeg, pdf, and libgit2 are forced deps
  19 # because they are automagically detected.
  20
  21 RDEPEND="
  22         app-text/ghostscript-gpl
  23         dev-libs/libgit2:=
  24         sci-astronomy/wcslib:0=
  25         sci-libs/cfitsio:0=
  26         sci-libs/gsl:0=
  27         virtual/jpeg:0=
  28 "
  29 DEPEND="${RDEPEND}"
  30
  31 src_prepare() {
  32         default
  33         sed -i -e 's/-O3//' configure.ac || die
  34         eautoreconf
  35 }
  36
  37 src_configure() {
  38         local myeconfargs=(
  39                 --enable-bin-op-alltypes
  40                 $(use_enable static-libs static)
  41                 $(use_enable threads)
  42         )
  43         econf ${myeconfargs[@]}
  44 }
  45
  46 src_install() {
  47         default
  48         use static-libs || prune_libtool_files --all
  49 }