net-wireless/hostapd/hostapd-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit toolchain-funcs systemd savedconfig
   7
   8 DESCRIPTION="IEEE 802.11 wireless LAN Host AP daemon"
   9 HOMEPAGE="http://w1.fi"
  10 EXTRAS_VER="2.7-r2"
  11 EXTRAS_NAME="${CATEGORY}_${PN}_${EXTRAS_VER}_extras"
  12 SRC_URI="https://dev.gentoo.org/~andrey_utkin/distfiles/${EXTRAS_NAME}.tar.xz"
  13
  14 if [[ $PV == 9999 ]]; then
  15         inherit git-r3
  16         EGIT_REPO_URI="https://w1.fi/hostap.git"
  17 else
  18         if [[ $PV =~ ^.*_p[0-9]{8}$ ]]; then
  19                 SRC_URI+=" https://dev.gentoo.org/~andrey_utkin/distfiles/${P}.tar.xz"
  20         else
  21                 SRC_URI+=" https://w1.fi/releases/${P}.tar.gz"
  22         fi
  23         # Never stabilize snapshot ebuilds please
  24         KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~x86"
  25 fi
  26
  27 LICENSE="BSD"
  28 SLOT="0"
  29 IUSE="internal-tls ipv6 libressl logwatch netlink sqlite +wps +crda"
  30
  31 DEPEND="
  32         libressl? ( dev-libs/libressl:0= )
  33         !libressl? (
  34                 internal-tls? ( dev-libs/libtommath )
  35                 !internal-tls? ( dev-libs/openssl:0=[-bindist] )
  36         )
  37         kernel_linux? (
  38                 dev-libs/libnl:3
  39                 crda? ( net-wireless/crda )
  40         )
  41         netlink? ( net-libs/libnfnetlink )
  42         sqlite? ( >=dev-db/sqlite-3 )"
  43
  44 RDEPEND="${DEPEND}"
  45
  46 S="${S}/${PN}"
  47
  48 pkg_pretend() {
  49         if use internal-tls; then
  50                 if use libressl; then
  51                         elog "libressl flag takes precedence over internal-tls"
  52                 else
  53                         ewarn "internal-tls implementation is experimental and provides fewer features"
  54                 fi
  55         fi
  56 }
  57
  58 src_unpack() {
  59         # Override default one because we need the SRC_URI ones even in case of 9999 ebuilds
  60         default
  61         if [[ ${PV} == 9999 ]] ; then
  62                 git-r3_src_unpack
  63         fi
  64 }
  65
  66 src_prepare() {
  67         # Allow users to apply patches to src/drivers for example,
  68         # i.e. anything outside ${S}/${PN}
  69         pushd ../ >/dev/null || die
  70         default
  71         popd >/dev/null || die
  72
  73         sed -i -e "s:/etc/hostapd:/etc/hostapd/hostapd:g" \
  74                 "${S}/hostapd.conf" || die
  75 }
  76
  77 src_configure() {
  78         local CONFIG="${S}/.config"
  79
  80         restore_config "${CONFIG}"
  81         if [[ -f "${CONFIG}" ]]; then
  82                 default_src_configure
  83                 return 0
  84         fi
  85
  86         # toolchain setup
  87         echo "CC = $(tc-getCC)" > ${CONFIG}
  88
  89         # EAP authentication methods
  90         echo "CONFIG_EAP=y" >> ${CONFIG}
  91         echo "CONFIG_ERP=y" >> ${CONFIG}
  92         echo "CONFIG_EAP_MD5=y" >> ${CONFIG}
  93         echo "CONFIG_SAE=y" >> ${CONFIG}
  94         echo "CONFIG_OWE=y" >> ${CONFIG}
  95         echo "CONFIG_DPP=y" >> ${CONFIG}
  96         echo "CONFIG_SUITEB=y" >> ${CONFIG}
  97         echo "CONFIG_SUITEB192=y" >> ${CONFIG}
  98
  99         if use internal-tls && ! use libressl; then
 100                 echo "CONFIG_TLS=internal" >> ${CONFIG}
 101         else
 102                 # SSL authentication methods
 103                 echo "CONFIG_EAP_FAST=y" >> ${CONFIG}
 104                 echo "CONFIG_EAP_TLS=y" >> ${CONFIG}
 105                 echo "CONFIG_EAP_TTLS=y" >> ${CONFIG}
 106                 echo "CONFIG_EAP_MSCHAPV2=y" >> ${CONFIG}
 107                 echo "CONFIG_EAP_PEAP=y" >> ${CONFIG}
 108                 echo "CONFIG_TLSV11=y" >> ${CONFIG}
 109                 echo "CONFIG_TLSV12=y" >> ${CONFIG}
 110                 echo "CONFIG_EAP_PWD=y" >> ${CONFIG}
 111         fi
 112
 113         if use wps; then
 114                 # Enable Wi-Fi Protected Setup
 115                 echo "CONFIG_WPS=y" >> ${CONFIG}
 116                 echo "CONFIG_WPS2=y" >> ${CONFIG}
 117                 echo "CONFIG_WPS_UPNP=y" >> ${CONFIG}
 118                 echo "CONFIG_WPS_NFC=y" >> ${CONFIG}
 119                 einfo "Enabling Wi-Fi Protected Setup support"
 120         fi
 121
 122         echo "CONFIG_EAP_IKEV2=y" >> ${CONFIG}
 123         echo "CONFIG_EAP_TNC=y" >> ${CONFIG}
 124         echo "CONFIG_EAP_GTC=y" >> ${CONFIG}
 125         echo "CONFIG_EAP_SIM=y" >> ${CONFIG}
 126         echo "CONFIG_EAP_AKA=y" >> ${CONFIG}
 127         echo "CONFIG_EAP_AKA_PRIME=y" >> ${CONFIG}
 128         echo "CONFIG_EAP_EKE=y" >> ${CONFIG}
 129         echo "CONFIG_EAP_PAX=y" >> ${CONFIG}
 130         echo "CONFIG_EAP_PSK=y" >> ${CONFIG}
 131         echo "CONFIG_EAP_SAKE=y" >> ${CONFIG}
 132         echo "CONFIG_EAP_GPSK=y" >> ${CONFIG}
 133         echo "CONFIG_EAP_GPSK_SHA256=y" >> ${CONFIG}
 134
 135         einfo "Enabling drivers: "
 136
 137         # drivers
 138         echo "CONFIG_DRIVER_HOSTAP=y" >> ${CONFIG}
 139         einfo "  HostAP driver enabled"
 140         echo "CONFIG_DRIVER_WIRED=y" >> ${CONFIG}
 141         einfo "  Wired driver enabled"
 142         echo "CONFIG_DRIVER_NONE=y" >> ${CONFIG}
 143         einfo "  None driver enabled"
 144
 145         einfo "  nl80211 driver enabled"
 146         echo "CONFIG_DRIVER_NL80211=y" >> ${CONFIG}
 147
 148         # epoll
 149         echo "CONFIG_ELOOP_EPOLL=y" >> ${CONFIG}
 150
 151         # misc
 152         echo "CONFIG_DEBUG_FILE=y" >> ${CONFIG}
 153         echo "CONFIG_PKCS12=y" >> ${CONFIG}
 154         echo "CONFIG_RADIUS_SERVER=y" >> ${CONFIG}
 155         echo "CONFIG_IAPP=y" >> ${CONFIG}
 156         echo "CONFIG_IEEE80211R=y" >> ${CONFIG}
 157         echo "CONFIG_IEEE80211W=y" >> ${CONFIG}
 158         echo "CONFIG_IEEE80211N=y" >> ${CONFIG}
 159         echo "CONFIG_IEEE80211AC=y" >> ${CONFIG}
 160         echo "CONFIG_PEERKEY=y" >> ${CONFIG}
 161         echo "CONFIG_RSN_PREAUTH=y" >> ${CONFIG}
 162         echo "CONFIG_INTERWORKING=y" >> ${CONFIG}
 163         echo "CONFIG_FULL_DYNAMIC_VLAN=y" >> ${CONFIG}
 164         echo "CONFIG_HS20=y" >> ${CONFIG}
 165         echo "CONFIG_WNM=y" >> ${CONFIG}
 166         echo "CONFIG_FST=y" >> ${CONFIG}
 167         echo "CONFIG_FST_TEST=y" >> ${CONFIG}
 168         echo "CONFIG_ACS=y" >> ${CONFIG}
 169
 170         if use netlink; then
 171                 # Netlink support
 172                 echo "CONFIG_VLAN_NETLINK=y" >> ${CONFIG}
 173         fi
 174
 175         if use ipv6; then
 176                 # IPv6 support
 177                 echo "CONFIG_IPV6=y" >> ${CONFIG}
 178         fi
 179
 180         if use sqlite; then
 181                 # Sqlite support
 182                 echo "CONFIG_SQLITE=y" >> ${CONFIG}
 183         fi
 184
 185         # If we are using libnl 2.0 and above, enable support for it
 186         # Removed for now, since the 3.2 version is broken, and we don't
 187         # support it.
 188         if has_version ">=dev-libs/libnl-3.2"; then
 189                 echo "CONFIG_LIBNL32=y" >> .config
 190         fi
 191
 192         # TODO: Add support for BSD drivers
 193
 194         default_src_configure
 195 }
 196
 197 src_compile() {
 198         emake V=1
 199
 200         if use libressl || ! use internal-tls; then
 201                 emake V=1 nt_password_hash
 202                 emake V=1 hlr_auc_gw
 203         fi
 204 }
 205
 206 src_install() {
 207         insinto /etc/${PN}
 208         doins ${PN}.{conf,accept,deny,eap_user,radius_clients,sim_db,wpa_psk}
 209
 210         fperms -R 600 /etc/${PN}
 211
 212         dosbin ${PN}
 213         dobin ${PN}_cli
 214
 215         if use libressl || ! use internal-tls; then
 216                 dobin nt_password_hash hlr_auc_gw
 217         fi
 218
 219         newinitd "${WORKDIR}/${EXTRAS_NAME}"/${PN}-init.d ${PN}
 220         newconfd "${WORKDIR}/${EXTRAS_NAME}"/${PN}-conf.d ${PN}
 221         systemd_dounit "${WORKDIR}/${EXTRAS_NAME}"/${PN}.service
 222
 223         doman ${PN}{.8,_cli.1}
 224
 225         dodoc ChangeLog README
 226         use wps && dodoc README-WPS
 227
 228         docinto examples
 229         dodoc wired.conf
 230
 231         if use logwatch; then
 232                 insinto /etc/log.d/conf/services/
 233                 doins logwatch/${PN}.conf
 234
 235                 exeinto /etc/log.d/scripts/services/
 236                 doexe logwatch/${PN}
 237         fi
 238
 239         save_config .config
 240 }
 241
 242 pkg_postinst() {
 243         einfo
 244         einfo "If you are running openRC you need to follow this instructions:"
 245         einfo "In order to use ${PN} you need to set up your wireless card"
 246         einfo "for master mode in /etc/conf.d/net and then start"
 247         einfo "/etc/init.d/${PN}."
 248         einfo
 249         einfo "Example configuration:"
 250         einfo
 251         einfo "config_wlan0=( \"192.168.1.1/24\" )"
 252         einfo "channel_wlan0=\"6\""
 253         einfo "essid_wlan0=\"test\""
 254         einfo "mode_wlan0=\"master\""
 255         einfo
 256         #if [ -e "${KV_DIR}"/net/mac80211 ]; then
 257         #       einfo "This package now compiles against the headers installed by"
 258         #       einfo "the kernel source for the mac80211 driver. You should "
 259         #       einfo "re-emerge ${PN} after upgrading your kernel source."
 260         #fi
 261
 262         if use wps; then
 263                 einfo "You have enabled Wi-Fi Protected Setup support, please"
 264                 einfo "read the README-WPS file in /usr/share/doc/${P}"
 265                 einfo "for info on how to use WPS"
 266         fi
 267 }