net-wireless/airtraf/airtraf-1.1-r3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils toolchain-funcs
   8
   9 DESCRIPTION="AirTraf 802.11b Wireless traffic sniffer"
  10 LICENSE="GPL-2"
  11 HOMEPAGE="http://www.elixar.com/"
  12 SRC_URI="${HOMEPAGE}${P}.tar.gz"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15
  16 RDEPEND="
  17         net-libs/libpcap
  18         sys-libs/ncurses
  19 "
  20 DEPEND="
  21         ${RDEPEND}
  22         virtual/pkgconfig
  23 "
  24
  25 src_prepare() {
  26         epatch \
  27                 "${FILESDIR}"/${P}.patch \
  28                 "${FILESDIR}"/${P}-off-by-one.patch \
  29                 "${FILESDIR}"/${P}-fprintf-format.patch
  30
  31         sed -i \
  32                 -e '/^LIBS/s|=.*|= $(shell $(PKG_CONFIG) --libs panel)|' \
  33                 src/libncurses/Makefile || die
  34         sed -i \
  35                 -e 's|-lpanel -lncurses|$(shell $(PKG_CONFIG) --libs panel)|' \
  36                 src/sniffd/Makefile || die
  37         tc-export PKG_CONFIG
  38 }
  39
  40 src_compile() {
  41         # parallel make (bug #297331)
  42         emake -C src -j1 \
  43                 CC=$(tc-getCC) \
  44                 CXX=$(tc-getCXX) \
  45                 CFLAGS="${CFLAGS}" \
  46                 CXXFLAGS="${CXXFLAGS}" \
  47                 LDFLAGS="${LDFLAGS}" \
  48                 || die
  49 }
  50
  51 src_install () {
  52         dobin src/airtraf
  53         dodoc Authors COMPATIBILITY docs/airtraf_doc.html
  54 }