net-vpn/tor/tor-0.4.2.5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5
   6 inherit flag-o-matic readme.gentoo-r1 systemd
   7
   8 MY_PV="$(ver_rs 4 -)"
   9 MY_PF="${PN}-${MY_PV}"
  10 DESCRIPTION="Anonymizing overlay network for TCP"
  11 HOMEPAGE="http://www.torproject.org/"
  12 SRC_URI="https://www.torproject.org/dist/${MY_PF}.tar.gz
  13         https://archive.torproject.org/tor-package-archive/${MY_PF}.tar.gz"
  14 S="${WORKDIR}/${MY_PF}"
  15
  16 LICENSE="BSD GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~ppc-macos"
  19 IUSE="caps doc libressl lzma +man scrypt seccomp selinux systemd tor-hardening test zstd"
  20
  21 DEPEND="
  22         dev-libs/libevent:=[ssl]
  23         sys-libs/zlib
  24         caps? ( sys-libs/libcap )
  25         man? ( app-text/asciidoc )
  26         !libressl? ( dev-libs/openssl:0=[-bindist] )
  27         libressl? ( dev-libs/libressl:0= )
  28         lzma? ( app-arch/xz-utils )
  29         scrypt? ( app-crypt/libscrypt )
  30         seccomp? ( >=sys-libs/libseccomp-2.4.1 )
  31         systemd? ( sys-apps/systemd )
  32         zstd? ( app-arch/zstd )"
  33 RDEPEND="
  34         acct-user/tor
  35         acct-group/tor
  36         ${DEPEND}
  37         selinux? ( sec-policy/selinux-tor )"
  38
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-0.2.7.4-torrc.sample.patch
  41         "${FILESDIR}"/${PN}-0.3.3.2-alpha-tor.service.in.patch
  42 )
  43
  44 DOCS=()
  45
  46 RESTRICT="!test? ( test )"
  47
  48 src_configure() {
  49         use doc && DOCS+=( README ChangeLog ReleaseNotes doc/HACKING )
  50         export ac_cv_lib_cap_cap_init=$(usex caps)
  51         econf \
  52                 --localstatedir="${EPREFIX}/var" \
  53                 --enable-system-torrc \
  54                 --disable-android \
  55                 --disable-html-manual \
  56                 --disable-libfuzzer \
  57                 --disable-module-dirauth \
  58                 --enable-pic \
  59                 --disable-rust \
  60                 --disable-restart-debugging \
  61                 --disable-zstd-advanced-apis  \
  62                 $(use_enable man asciidoc) \
  63                 $(use_enable man manpage) \
  64                 $(use_enable lzma) \
  65                 $(use_enable scrypt libscrypt) \
  66                 $(use_enable seccomp) \
  67                 $(use_enable systemd) \
  68                 $(use_enable tor-hardening gcc-hardening) \
  69                 $(use_enable tor-hardening linker-hardening) \
  70                 $(use_enable test unittests) \
  71                 $(use_enable test coverage) \
  72                 $(use_enable zstd)
  73 }
  74
  75 src_install() {
  76         default
  77         readme.gentoo_create_doc
  78
  79         newconfd "${FILESDIR}"/tor.confd tor
  80         newinitd "${FILESDIR}"/tor.initd-r9 tor
  81         systemd_dounit contrib/dist/tor.service
  82
  83         keepdir /var/lib/tor
  84
  85         fperms 750 /var/lib/tor
  86         fowners tor:tor /var/lib/tor
  87
  88         insinto /etc/tor/
  89         newins "${FILESDIR}"/torrc-r2 torrc
  90 }