net-vpn/networkmanager-openvpn/networkmanager-openvpn-1.8.10.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
   6
   7 inherit gnome2 user
   8
   9 DESCRIPTION="NetworkManager OpenVPN plugin"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm x86"
  15 IUSE="gtk test"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.32:2
  20         >=net-misc/networkmanager-1.7.0:=
  21         >=net-vpn/openvpn-2.1
  22         gtk? (
  23                 >=app-crypt/libsecret-0.18
  24                 >=gnome-extra/nm-applet-1.7.0
  25                 >=x11-libs/gtk+-3.4:3
  26         )
  27 "
  28 DEPEND="${RDEPEND}
  29         dev-libs/libxml2:2
  30         sys-devel/gettext
  31         >=dev-util/intltool-0.35
  32         virtual/pkgconfig
  33 "
  34
  35 pkg_setup() {
  36         enewgroup nm-openvpn
  37         enewuser nm-openvpn -1 -1 -1 nm-openvpn
  38 }
  39
  40 src_prepare() {
  41         # Test will fail if the machine doesn't have a particular locale installed
  42         # FAIL: (tls-import-data) unexpected 'ca' secret value, upstream bug #742708
  43         sed '/test_non_utf8_import (plugin, test_dir)/ d' \
  44                 -i properties/tests/test-import-export.c || die "sed failed"
  45
  46         gnome2_src_prepare
  47 }
  48
  49 src_configure() {
  50         # --localstatedir=/var needed per bug #536248
  51         gnome2_src_configure \
  52                 --localstatedir=/var \
  53                 --disable-more-warnings \
  54                 --disable-static \
  55                 --with-dist-version=Gentoo \
  56                 $(use_with gtk gnome)
  57 }