net-voip/telepathy-salut/telepathy-salut-0.8.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 inherit python-any-r1
   8
   9 DESCRIPTION="A link-local XMPP connection manager for Telepathy"
  10 HOMEPAGE="https://telepathy.freedesktop.org/"
  11 SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
  12
  13 LICENSE="LGPL-2.1"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
  16 IUSE="gnutls test"
  17
  18 RDEPEND="
  19         >=dev-libs/dbus-glib-0.61
  20         dev-libs/libxml2
  21         >=dev-libs/glib-2.28:2
  22         >=sys-apps/dbus-1.1.0
  23         >=net-libs/telepathy-glib-0.17.1
  24         >=net-dns/avahi-0.6.22[dbus]
  25         net-libs/libsoup:2.4
  26         sys-apps/util-linux
  27         dev-db/sqlite:3
  28         gnutls? ( >=net-libs/gnutls-2.10.2 )
  29         !gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
  30 "
  31 DEPEND="${RDEPEND}
  32         ${PYTHON_DEPS}
  33         dev-libs/libxslt
  34         virtual/pkgconfig
  35         test? (
  36                 >=dev-libs/check-0.9.4
  37                 net-libs/libgsasl
  38                 || (
  39                         $(python_gen_any_dep 'dev-python/twisted[${PYTHON_USEDEP}]')
  40                         $(python_gen_any_dep 'dev-python/twisted-words[${PYTHON_USEDEP}]')
  41                 )
  42         )
  43 "
  44 # FIXME: needs xmppstream python module
  45 #               >=net-dns/avahi-0.6.22[python]
  46
  47 PATCHES=(
  48         # Fix uninitialized variable, upstream bug #37701
  49         "${FILESDIR}"/${PN}-0.5.0-uninitialized.patch
  50 )
  51
  52 python_check_deps() {
  53         if use test ; then
  54                  has_version "dev-python/twisted[${PYTHON_USEDEP}]" \
  55                         || has_version "dev-python/twisted-words[${PYTHON_USEDEP}]"
  56         fi
  57 }
  58
  59 pkg_setup() {
  60         python-any-r1_pkg_setup
  61 }
  62
  63 src_configure() {
  64         econf \
  65                 --disable-coding-style-checks \
  66                 --disable-plugins \
  67                 --disable-Werror \
  68                 --disable-static \
  69                 --disable-avahi-tests \
  70                 --docdir=/usr/share/doc/${PF} \
  71                 --with-tls=$(usex gnutls gnutls openssl)
  72                 #$(use_enable test avahi-tests)
  73 }
  74
  75 src_install() {
  76         MAKEOPTS+=" -j1" default # bug 413581
  77         find "${D}" -name '*.la' -delete || die
  78 }