net-news/quiterss/quiterss-0.19.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit qmake-utils xdg
   7
   8 DESCRIPTION="A Qt-based RSS/Atom feed reader"
   9 HOMEPAGE="https://quiterss.org"
  10
  11 if [[ ${PV} == *9999* ]]; then
  12         EGIT_REPO_URI="https://github.com/QuiteRSS/quiterss.git"
  13         inherit git-r3
  14 else
  15         SRC_URI="https://github.com/QuiteRSS/quiterss/archive/${PV}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="amd64 ~arm x86 ~amd64-linux ~x86-linux"
  17 fi
  18
  19 LICENSE="GPL-3"
  20 SLOT="0"
  21 IUSE=""
  22
  23 BDEPEND="
  24         dev-qt/linguist-tools:5
  25         virtual/pkgconfig
  26 "
  27 DEPEND="
  28         >=dev-db/sqlite-3.11.1:3
  29         dev-qt/qtcore:5
  30         dev-qt/qtgui:5
  31         dev-qt/qtmultimedia:5
  32         dev-qt/qtnetwork:5[ssl]
  33         dev-qt/qtprintsupport:5
  34         dev-qt/qtsingleapplication[X,qt5(+)]
  35         dev-qt/qtsql:5[sqlite]
  36         dev-qt/qtwebkit:5
  37         dev-qt/qtwidgets:5
  38         dev-qt/qtxml:5
  39 "
  40 RDEPEND="${DEPEND}"
  41
  42 src_prepare() {
  43         default
  44         sed -e "s/exists(.git)/0/" -i QuiteRSS.pro || die
  45 }
  46
  47 src_configure() {
  48         local myqmakeargs=(
  49                 PREFIX="${EPREFIX}/usr"
  50                 SYSTEMQTSA=1
  51         )
  52         eqmake5 "${myqmakeargs[@]}"
  53 }
  54
  55 src_install() {
  56         emake INSTALL_ROOT="${D}" install
  57         einstalldocs
  58 }