net-nds/tac_plus/tac_plus-4.0.4.27a.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit autotools base libtool
   7
   8 MY_P="tacacs+-F${PV}"
   9 S="${WORKDIR}/${MY_P}"
  10
  11 DESCRIPTION="An updated version of Cisco's TACACS+ server"
  12 HOMEPAGE="http://www.shrubbery.net/tac_plus/"
  13 SRC_URI="ftp://ftp.shrubbery.net/pub/tac_plus/${MY_P}.tar.gz"
  14
  15 LICENSE="HPND RSA GPL-2" # GPL-2 only for init script
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~ppc ~x86"
  18 IUSE="debug finger maxsess tcpd skey static-libs"
  19
  20 DEPEND="skey? ( >=sys-auth/skey-1.1.5-r1 )
  21         tcpd? ( sys-apps/tcp-wrappers )
  22         sys-libs/pam"
  23 RDEPEND="${DEPEND}"
  24
  25 PATCHES=(
  26         "${FILESDIR}/${P}-parallelmake.patch"
  27         "${FILESDIR}/${P}-deansification.patch"
  28 )
  29
  30 src_prepare() {
  31         base_src_prepare
  32         mv configure.in configure.ac || die "Unable to quiet autoconf deprecation warning"
  33         AT_M4DIR="." eautoreconf
  34         elibtoolize
  35 }
  36
  37 src_configure() {
  38         econf \
  39                 $(use_with skey) \
  40                 $(use_with tcpd libwrap) \
  41                 $(use_enable debug) \
  42                 $(use_enable finger) \
  43                 $(use_enable maxsess) \
  44                 $(use_enable static-libs static)
  45 }
  46
  47 src_install() {
  48         emake DESTDIR="${D}" install
  49
  50         use static-libs || find "${D}" -name '*.la' -delete || die "Unable to remove spurious libtool archive"
  51         dodoc CHANGES FAQ
  52
  53         newinitd "${FILESDIR}/tac_plus.init2" tac_plus
  54         newconfd "${FILESDIR}/tac_plus.confd2" tac_plus
  55
  56         insinto /etc/tac_plus
  57         newins "${FILESDIR}/tac_plus.conf2" tac_plus.conf
  58 }