net-misc/zerotier/zerotier-1.4.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic llvm systemd toolchain-funcs
   7
   8 HOMEPAGE="https://www.zerotier.com/"
   9 DESCRIPTION="A software-based managed Ethernet switch for planet Earth"
  10 SRC_URI="https://github.com/zerotier/ZeroTierOne/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSL-1.1"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  15 IUSE="clang neon"
  16
  17 S="${WORKDIR}/ZeroTierOne-${PV}"
  18
  19 RDEPEND="
  20         dev-libs/json-glib
  21         net-libs/libnatpmp
  22         net-libs/miniupnpc:=
  23         clang? ( >=sys-devel/clang-6:* )"
  24
  25 DEPEND="${RDEPEND}"
  26
  27 PATCHES=( "${FILESDIR}/${P}-respect-ldflags.patch"
  28         "${FILESDIR}/${P}-add-armv7a-support.patch"
  29         "${FILESDIR}/${P}-fixup-neon-support.patch" )
  30
  31 DOCS=( README.md AUTHORS.md )
  32
  33 LLVM_MAX_SLOT=9
  34
  35 llvm_check_deps() {
  36         if use clang ; then
  37                 if ! has_version --host-root "sys-devel/clang:${LLVM_SLOT}" ; then
  38                         ewarn "sys-devel/clang:${LLVM_SLOT} is missing! Cannot use LLVM slot ${LLVM_SLOT} ..."
  39                         return 1
  40                 fi
  41
  42                 if ! has_version --host-root "=sys-devel/lld-${LLVM_SLOT}*" ; then
  43                         ewarn "=sys-devel/lld-${LLVM_SLOT}* is missing! Cannot use LLVM slot ${LLVM_SLOT} ..."
  44                         return 1
  45                 fi
  46
  47                 einfo "Will use LLVM slot ${LLVM_SLOT}!"
  48         fi
  49 }
  50
  51 pkg_setup() {
  52         if use clang && ! tc-is-clang ; then
  53                 export CC=${CHOST}-clang
  54                 export CXX=${CHOST}-clang++
  55         else
  56                 tc-export CXX CC
  57         fi
  58         use neon || export ZT_DISABLE_NEON=1
  59 }
  60
  61 src_compile() {
  62         append-ldflags -Wl,-z,noexecstack
  63         emake CXX="${CXX}" STRIP=: one
  64 }
  65
  66 src_test() {
  67         emake selftest
  68         ./zerotier-selftest || die
  69 }
  70
  71 src_install() {
  72         default
  73         # remove pre-zipped man pages
  74         rm "${ED}"/usr/share/man/{man1,man8}/* || die
  75
  76         newinitd "${FILESDIR}/${PN}".init "${PN}"
  77         systemd_dounit "${FILESDIR}/${PN}".service
  78         doman doc/zerotier-{cli.1,idtool.1,one.8}
  79 }