net-misc/youtube-viewer/youtube-viewer-3.2.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils gnome2-utils perl-module vcs-snapshot
   8
   9 DESCRIPTION="A command line utility for viewing youtube-videos in Mplayer"
  10 HOMEPAGE="https://trizen.googlecode.com"
  11 SRC_URI="https://github.com/trizen/youtube-viewer/tarball/${PV} -> ${P}.tar.gz"
  12
  13 LICENSE="|| ( Artistic GPL-1+ )"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="gtk"
  17
  18 RDEPEND="
  19         >=dev-lang/perl-5.16.0
  20         dev-perl/Data-Dump
  21         dev-perl/JSON
  22         dev-perl/libwww-perl[ssl]
  23         dev-perl/Term-ReadLine-Gnu
  24         virtual/perl-Encode
  25         virtual/perl-File-Path
  26         virtual/perl-File-Spec
  27         virtual/perl-Getopt-Long
  28         virtual/perl-Scalar-List-Utils
  29         virtual/perl-Term-ANSIColor
  30         virtual/perl-Term-ReadLine
  31         virtual/perl-Text-ParseWords
  32         virtual/perl-Text-Tabs+Wrap
  33         gtk? (
  34                 dev-perl/File-ShareDir
  35                 >=dev-perl/gtk2-perl-1.244.0
  36                 virtual/freedesktop-icon-theme
  37                 x11-libs/gdk-pixbuf:2[X,jpeg]
  38         )"
  39 DEPEND="dev-perl/Module-Build"
  40
  41 SRC_TEST="do"
  42
  43 src_prepare() {
  44         perl-module_src_prepare
  45 }
  46
  47 # build system installs files on "perl Build.PL" too
  48 # do all the work in src_install
  49 src_configure() { :; }
  50 src_compile() { :; }
  51
  52 src_install() {
  53         local myconf
  54         if use gtk ; then
  55                 myconf="--gtk-youtube-viewer"
  56         fi
  57         perl-module_src_configure
  58         perl-module_src_install
  59
  60         if use gtk ; then
  61                 domenu share/gtk-youtube-viewer.desktop
  62                 doicon share/icons/gtk-youtube-viewer.png
  63         fi
  64 }
  65
  66 pkg_preinst() {
  67         use gtk && gnome2_icon_savelist
  68         perl_set_version
  69 }
  70
  71 pkg_postinst() {
  72         use gtk && gnome2_icon_cache_update
  73         elog "Optional dependencies:"
  74         optfeature "cache support" dev-perl/LWP-UserAgent-Cached
  75         optfeature "better STDIN support" dev-perl/Term-ReadLine-Gnu
  76         optfeature "faster JSON to HASH conversion" dev-perl/JSON-XS
  77         optfeature "the case if there are SSL problems" dev-perl/Mozilla-CA
  78         optfeature "printing results in a fixed-width format (--fixed-width, -W)" dev-perl/Text-CharWidth
  79         optfeature "threads support" virtual/perl-threads
  80         elog
  81         elog "You also need a compatible video player, possible choices are:"
  82         elog "  media-video/mpv"
  83         elog "  media-video/smplayer"
  84         elog "  media-video/vlc"
  85         elog "Also check the configuration file in ~/.config/youtube-viewer/"
  86         elog "and configure your video player backend."
  87 }
  88
  89 pkg_postrm() {
  90         use gtk && gnome2_icon_cache_update
  91 }