net-misc/x2goserver/x2goserver-4.1.0.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit multilib systemd toolchain-funcs user xdg
   6
   7 DESCRIPTION="The X2Go server"
   8 HOMEPAGE="http://www.x2go.org"
   9 SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="+fuse postgres +sqlite"
  15
  16 REQUIRED_USE="|| ( postgres sqlite )"
  17
  18 DEPEND="virtual/perl-ExtUtils-MakeMaker"
  19 RDEPEND="dev-lang/perl:=
  20         dev-perl/Capture-Tiny
  21         dev-perl/Config-Simple
  22         dev-perl/File-BaseDir
  23         dev-perl/File-ReadBackwards
  24         dev-perl/File-Which
  25         dev-perl/Switch
  26         dev-perl/Try-Tiny
  27         media-fonts/font-cursor-misc
  28         media-fonts/font-misc-misc[nls]
  29         >=net-misc/nx-3.5.99.14
  30         net-misc/openssh
  31         >=sys-apps/iproute2-4.3.0
  32         x11-apps/xauth
  33         x11-apps/xhost
  34         x11-apps/xwininfo
  35         fuse? ( net-fs/sshfs )
  36         postgres? ( dev-perl/DBD-Pg )
  37         sqlite? ( dev-perl/DBD-SQLite )"
  38
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-4.1.0.0-Xresources.patch
  41         "${FILESDIR}"/${PN}-4.1.0.0-skip_man2html.patch
  42         )
  43
  44 pkg_setup() {
  45         # Force the group creation, #479650
  46         enewgroup x2gouser
  47         enewgroup x2goprint
  48         enewuser x2gouser -1 -1 /var/lib/x2go x2gouser
  49         enewuser x2goprint -1 -1 /var/spool/x2goprint x2goprint
  50 }
  51
  52 src_prepare() {
  53         default
  54         # Multilib clean
  55         sed -e "s#/lib/#/$(get_libdir)/#" -i x2goserver/bin/x2gopath || die
  56
  57         # Do not compress man pages by default
  58         sed '/^[[:space:]]*gzip.*man/d' -i */Makefile || die
  59 }
  60
  61 src_compile() {
  62         emake \
  63                 CC="$(tc-getCC)" \
  64                 LIBDIR="/usr/$(get_libdir)/x2go" \
  65                 PREFIX=/usr
  66 }
  67
  68 src_install() {
  69         emake \
  70                 DESTDIR="${D}" \
  71                 LIBDIR="/usr/$(get_libdir)/x2go" \
  72                 NXLIBDIR="/usr/$(get_libdir)/nx" \
  73                 PREFIX=/usr \
  74                 install
  75
  76         fowners root:x2goprint /usr/bin/x2goprint
  77         fperms 2755 /usr/bin/x2goprint
  78         fperms 0750 /etc/sudoers.d
  79         fperms 0440 /etc/sudoers.d/x2goserver
  80         dosym ../../usr/share/applications /etc/x2go/applications
  81
  82         newinitd "${FILESDIR}"/${PN}.init x2gocleansessions
  83         systemd_dounit "${FILESDIR}"/x2gocleansessions.service
  84 }
  85
  86 pkg_postinst() {
  87         xdg_pkg_postinst
  88         if use sqlite ; then
  89                 if [[ -f "${EROOT}"/var/lib/x2go/x2go_sessions ]] ; then
  90                         elog "To use sqlite and update your existing database, run:"
  91                         elog " # x2godbadmin --updatedb"
  92                 else
  93                         elog "To use sqlite and create the initial database, run:"
  94                         elog " # x2godbadmin --createdb"
  95                 fi
  96
  97         fi
  98         if use postgres ; then
  99                 elog "To use a PostgreSQL database, more information is availabe here:"
 100                 elog "http://www.x2go.org/doku.php/wiki:advanced:multi-node:x2goserver-pgsql"
 101         fi
 102
 103         elog "For password authentication, you need to enable PasswordAuthentication"
 104         elog "in /etc/ssh/sshd_config (disabled by default in Gentoo)"
 105         elog "An init script was installed for x2gocleansessions"
 106 }