net-misc/x2goclient/x2goclient-4.1.1.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils gnome2-utils qmake-utils
   7
   8 DESCRIPTION="The X2Go Qt client"
   9 HOMEPAGE="http://www.x2go.org"
  10 SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="ldap"
  16
  17 COMMON_DEPEND="dev-qt/qtcore:5
  18         dev-qt/qtgui:5
  19         dev-qt/qtnetwork:5[ssl]
  20         dev-qt/qtsvg:5
  21         dev-qt/qtwidgets:5
  22         dev-qt/qtx11extras:5
  23         >=net-libs/libssh-0.7.5-r2
  24         net-print/cups
  25         x11-libs/libXpm
  26         ldap? ( net-nds/openldap )"
  27 DEPEND="${COMMON_DEPEND}
  28         dev-qt/linguist-tools:5"
  29 RDEPEND="${COMMON_DEPEND}
  30         net-misc/nx"
  31
  32 CLIENT_BUILD="${WORKDIR}"/${P}.client_build
  33 PLUGIN_BUILD="${WORKDIR}"/${P}.plugin_build
  34
  35 src_prepare() {
  36         default
  37
  38         if ! use ldap; then
  39                 sed -e "s/-lldap//" -i x2goclient.pro || die
  40                 sed -e "s/#define USELDAP//" -i src/x2goclientconfig.h || die
  41         fi
  42 }
  43
  44 src_configure() {
  45         eqmake5 "${S}"/x2goclient.pro
  46 }
  47
  48 src_install() {
  49         dobin ${PN}
  50
  51         local size
  52         for size in 16 32 48 64 128 ; do
  53                 doicon -s ${size} res/img/icons/${size}x${size}/${PN}.png
  54         done
  55         newicon -s scalable res/img/icons/hildon/${PN}_hildon.svg ${PN}.svg
  56
  57         insinto /usr/share/pixmaps
  58         doins res/img/icons/${PN}.xpm
  59
  60         domenu desktop/${PN}.desktop
  61         doman man/man?/*
  62 }
  63
  64 pkg_postinst() {
  65         gnome2_icon_cache_update
  66 }
  67
  68 pkg_postrm() {
  69         gnome2_icon_cache_update
  70 }