net-misc/vino/vino-3.22.0-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_EAUTORECONF="yes"
   6 inherit gnome2 systemd
   7
   8 DESCRIPTION="An integrated VNC server for GNOME"
   9 HOMEPAGE="https://wiki.gnome.org/Projects/Vino"
  10 SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
  15 IUSE="crypt debug gnome-keyring ipv6 jpeg ssl +telepathy zeroconf +zlib"
  16 # bug #394611; tight encoding requires zlib encoding
  17 REQUIRED_USE="jpeg? ( zlib )"
  18
  19 # cairo used in vino-fb
  20 # libSM and libICE used in eggsmclient-xsmp
  21 RDEPEND="
  22         >=dev-libs/glib-2.26:2
  23         >=dev-libs/libgcrypt-1.1.90:0=
  24         >=x11-libs/gtk+-3:3
  25
  26         x11-libs/cairo:=
  27         x11-libs/libICE
  28         x11-libs/libSM
  29         x11-libs/libX11
  30         x11-libs/libXdamage
  31         x11-libs/libXext
  32         x11-libs/libXfixes
  33         x11-libs/libXtst
  34         x11-libs/pango[X]
  35
  36         >=x11-libs/libnotify-0.7.0:=
  37
  38         crypt? ( >=dev-libs/libgcrypt-1.1.90:0= )
  39         gnome-keyring? ( app-crypt/libsecret )
  40         jpeg? ( virtual/jpeg:0= )
  41         ssl? ( >=net-libs/gnutls-2.2.0:= )
  42         telepathy? (
  43                 dev-libs/dbus-glib
  44                 >=net-libs/telepathy-glib-0.18 )
  45         zeroconf? ( >=net-dns/avahi-0.6:=[dbus] )
  46         zlib? ( sys-libs/zlib:= )
  47 "
  48 DEPEND="${RDEPEND}
  49         app-crypt/libsecret
  50         dev-util/glib-utils
  51         >=dev-util/intltool-0.50
  52         gnome-base/gnome-common
  53         virtual/pkgconfig
  54 "
  55 # libsecret is always required at build time per bug 322763
  56 # eautoreconf needs gnome-common
  57
  58 PATCHES=(
  59         "${WORKDIR}"/patches/ # Patches from master branch at 2020-02-15 state; needs autoreconf
  60         "${FILESDIR}"/CVE-2014-6053.patch
  61         "${FILESDIR}"/CVE-2018-7225.patch
  62         "${FILESDIR}"/CVE-2019-15681.patch
  63 )
  64
  65 src_configure() {
  66         gnome2_src_configure \
  67                 $(use_enable ipv6) \
  68                 $(use_with crypt gcrypt) \
  69                 $(usex debug --enable-debug=yes ' ') \
  70                 $(use_with gnome-keyring secret) \
  71                 $(use_with jpeg) \
  72                 $(use_with ssl gnutls) \
  73                 $(use_with telepathy) \
  74                 $(use_with zeroconf avahi) \
  75                 $(use_with zlib) \
  76                 --with-systemduserunitdir="$(systemd_get_userunitdir)"
  77 }