net-misc/vinagre/vinagre-3.22.0-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools gnome2 linux-info vala
   6
   7 DESCRIPTION="VNC client for the GNOME desktop"
   8 HOMEPAGE="https://wiki.gnome.org/Apps/Vinagre"
   9
  10 LICENSE="GPL-3+"
  11 SLOT="0"
  12 KEYWORDS="amd64 ~arm ~ia64 ~ppc ~ppc64 x86"
  13 IUSE="rdp +ssh spice +telepathy zeroconf"
  14
  15 # cairo used in vinagre-tab
  16 # gdk-pixbuf used all over the place
  17 RDEPEND="
  18         >=dev-libs/glib-2.32.0:2
  19         >=x11-libs/gtk+-3.9.6:3
  20         app-crypt/libsecret
  21         >=dev-libs/libxml2-2.6.31:2
  22         >=net-libs/gtk-vnc-0.4.3[gtk3]
  23         x11-libs/cairo:=
  24         x11-libs/gdk-pixbuf:2
  25         x11-themes/hicolor-icon-theme
  26
  27         rdp? ( >=net-misc/freerdp-1.1:= )
  28         ssh? ( >=x11-libs/vte-0.20:2.91 )
  29         spice? (
  30                 app-emulation/spice-protocol
  31                 >=net-misc/spice-gtk-0.5[gtk3] )
  32         telepathy? (
  33                 dev-libs/dbus-glib
  34                 >=net-libs/telepathy-glib-0.11.6 )
  35         zeroconf? ( >=net-dns/avahi-0.6.26[dbus,gtk3] )
  36 "
  37 DEPEND="${RDEPEND}
  38         $(vala_depend)
  39         app-text/yelp-tools
  40         dev-libs/appstream-glib
  41         >=dev-util/intltool-0.50
  42         >=sys-devel/gettext-0.17
  43         virtual/pkgconfig
  44
  45         gnome-base/gnome-common
  46 "
  47 # gnome-base/gnome-common needed for eautoreconf
  48 pkg_pretend() {
  49         # Needed for VNC ssh tunnel, bug #518574
  50         CONFIG_CHECK="~IPV6"
  51         check_extra_config
  52 }
  53
  54 src_prepare() {
  55         # https://bugzilla.gnome.org/show_bug.cgi?id=765444
  56         eapply "${FILESDIR}"/${PN}-3.20.2-freerdp2.patch
  57         vala_src_prepare
  58         eautoreconf
  59         gnome2_src_prepare
  60 }
  61
  62 src_configure() {
  63         gnome2_src_configure \
  64                 $(use_enable rdp) \
  65                 $(use_enable ssh) \
  66                 $(use_enable spice) \
  67                 $(use_with telepathy) \
  68                 $(use_with zeroconf avahi)
  69 }