net-misc/s6-networking/s6-networking-2.3.0.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Suite of small networking utilities for Unix systems"
   7 HOMEPAGE="https://www.skarnet.org/software/s6-networking/"
   8 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
   9
  10 LICENSE="ISC"
  11 SLOT="0/$(ver_cut 1-2)"
  12 KEYWORDS="~amd64 ~x86"
  13 IUSE="ssl static static-libs"
  14
  15 REQUIRED_USE="static? ( static-libs )"
  16
  17 RDEPEND=">=dev-lang/execline-2.5.1.0:=[static-libs?]
  18         >=dev-libs/skalibs-2.8.0.0:=[static-libs?]
  19         >=sys-apps/s6-2.8.0.0:=[static-libs?]
  20         !static? (
  21                 >=net-dns/s6-dns-2.3.0.2:=
  22                 ssl? ( >=dev-libs/libressl-2.7.4:= )
  23         )
  24 "
  25 DEPEND="${RDEPEND}
  26         >=net-dns/s6-dns-2.3.0.2[static-libs?]
  27         ssl? ( >=dev-libs/libressl-2.7.4[static-libs?] )
  28 "
  29
  30 HTML_DOCS=( doc/. )
  31
  32 src_prepare() {
  33         default
  34
  35         # Avoid QA warning for LDFLAGS addition; avoid overriding -fstack-protector
  36         sed -i -e 's/.*-Wl,--hash-style=both$/:/' -e '/-fno-stack-protector$/d' \
  37                 configure || die
  38 }
  39
  40 src_configure() {
  41         econf \
  42                 --bindir=/bin \
  43                 --dynlibdir=/usr/$(get_libdir) \
  44                 --libdir=/usr/$(get_libdir)/${PN} \
  45                 --with-dynlib=/usr/$(get_libdir) \
  46                 --with-lib=/usr/$(get_libdir)/s6 \
  47                 --with-lib=/usr/$(get_libdir)/s6-dns \
  48                 --with-lib=/usr/$(get_libdir)/skalibs \
  49                 --with-sysdeps=/usr/$(get_libdir)/skalibs \
  50                 --enable-shared \
  51                 $(use_enable ssl ssl libressl) \
  52                 $(use_enable static allstatic) \
  53                 $(use_enable static static-libc) \
  54                 $(use_enable static-libs static)
  55 }