net-misc/rygel/rygel-0.38.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit gnome2 systemd
   8
   9 DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/Rygel"
  11
  12 LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE="X +introspection +sqlite tracker test transcode"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.44.0:2
  20         >=dev-libs/libgee-0.8:0.8
  21         >=dev-libs/libxml2-2.7:2
  22         >=media-libs/gupnp-dlna-0.9.4:2.0
  23         >=media-libs/gstreamer-1.12:1.0
  24         >=media-libs/gst-plugins-base-1.12:1.0
  25         >=media-libs/libmediaart-0.7:2.0
  26         media-plugins/gst-plugins-soup:1.0
  27         >=net-libs/gssdp-1.1.0:0=
  28         >=net-libs/gupnp-1.1.0:0=
  29         >=net-libs/gupnp-av-0.12.8
  30         >=net-libs/libsoup-2.44:2.4
  31         >=sys-apps/util-linux-2.20
  32         x11-misc/shared-mime-info
  33         introspection? ( >=dev-libs/gobject-introspection-1.33.4:= )
  34         sqlite? (
  35                 >=dev-db/sqlite-3.5:3
  36                 dev-libs/libunistring:=
  37                 x11-libs/gdk-pixbuf:2
  38         )
  39         tracker? ( app-misc/tracker:= )
  40         transcode? (
  41                 media-libs/gst-plugins-bad:1.0
  42                 media-plugins/gst-plugins-twolame:1.0
  43                 media-plugins/gst-plugins-libav:1.0
  44         )
  45         X? ( >=x11-libs/gtk+-3.22:3 )
  46 "
  47 DEPEND="${RDEPEND}
  48         dev-util/gtk-doc-am
  49         >=sys-devel/gettext-0.19.7
  50         virtual/pkgconfig
  51 "
  52 # Maintainer only
  53 #   app-text/docbook-xsl-stylesheets
  54 #       >=dev-lang/vala-0.36
  55 #   dev-libs/libxslt
  56
  57 src_prepare() {
  58         # Disable test triggering call to gst-plugins-scanner which causes
  59         # sandbox issues when plugins such as clutter are installed
  60         sed -e 's/return rygel_playbin_renderer_test_main (argv, argc);/return 0;/' \
  61                 -i tests/rygel-playbin-renderer-test.c || die
  62
  63         gnome2_src_prepare
  64 }
  65
  66 src_configure() {
  67         # We set xsltproc because man pages are provided by upstream
  68         # and we do not want to regenerate them automagically.
  69         gnome2_src_configure \
  70                 XSLTPROC=$(type -P false) \
  71                 --enable-gst-launch-plugin \
  72                 --with-media-engine=gstreamer \
  73                 --enable-nls \
  74                 --with-systemduserunitdir=$(systemd_get_userunitdir) \
  75                 $(use_enable introspection) \
  76                 $(use_enable sqlite media-export-plugin) \
  77                 $(use_enable sqlite lms-plugin) \
  78                 $(use_enable test tests) \
  79                 $(use_enable tracker tracker-plugin) \
  80                 $(use_with X ui)
  81 }