net-misc/rdesktop/rdesktop-1.8.3-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools eutils
   6
   7 MY_PV=${PV/_/-}
   8
   9 DESCRIPTION="A Remote Desktop Protocol Client"
  10 HOMEPAGE="http://rdesktop.sourceforge.net/"
  11 SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="alsa ao debug ipv6 kerberos libsamplerate oss pcsc-lite xrandr"
  17
  18 S=${WORKDIR}/${PN}-${MY_PV}
  19
  20 RDEPEND=">=dev-libs/openssl-0.9.6b:=
  21         x11-libs/libX11
  22         x11-libs/libXext
  23         x11-libs/libXau
  24         x11-libs/libXdmcp
  25         alsa? ( media-libs/alsa-lib )
  26         ao? ( >=media-libs/libao-0.8.6 )
  27         kerberos? ( net-libs/libgssglue )
  28         libsamplerate? ( media-libs/libsamplerate )
  29         pcsc-lite? ( >=sys-apps/pcsc-lite-1.6.6 )
  30         xrandr? ( x11-libs/libXrandr )"
  31 DEPEND="${RDEPEND}
  32         virtual/pkgconfig
  33         x11-libs/libXt"
  34
  35 src_prepare() {
  36         # Prevent automatic stripping
  37         local strip="$(echo '$(STRIP) $(DESTDIR)$(bindir)/rdesktop')"
  38         sed -i -e "s:${strip}::" Makefile.in \
  39                 || die "sed failed in Makefile.in"
  40
  41         # Automagic dependencies
  42         epatch "${FILESDIR}"/${PN}-1.6.0-sound_configure.patch
  43         epatch "${FILESDIR}"/${P}-xrandr_configure.patch
  44
  45         epatch_user
  46
  47         eautoreconf
  48 }
  49
  50 src_configure() {
  51         if use ao; then
  52                 sound_conf=$(use_with ao sound libao)
  53         else if use alsa; then
  54                         sound_conf=$(use_with alsa sound alsa)
  55                 else
  56                         sound_conf=$(use_with oss sound oss)
  57                 fi
  58         fi
  59
  60         econf \
  61                 --with-openssl="${EPREFIX}"/usr \
  62                 $(use_with debug) \
  63                 $(use_with ipv6) \
  64                 $(use_with libsamplerate) \
  65                 $(use_with xrandr) \
  66                 $(use_enable kerberos credssp) \
  67                 $(use_enable pcsc-lite smartcard) \
  68                 ${sound_conf}
  69 }
  70
  71 src_install() {
  72         emake DESTDIR="${D}" install
  73         dodoc doc/HACKING doc/TODO doc/keymapping.txt
  74 }