net-misc/radvd/radvd-2.12.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit systemd user eutils readme.gentoo
   8
   9 DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
  10 HOMEPAGE="http://v6web.litech.org/radvd/"
  11 SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"
  12
  13 LICENSE="BSD"
  14 SLOT="0"
  15 KEYWORDS="amd64 arm ~arm64 ~hppa ~ppc ~sparc ~x86 ~x86-fbsd"
  16 IUSE="kernel_FreeBSD selinux test"
  17
  18 CDEPEND="dev-libs/libdaemon"
  19 DEPEND="${CDEPEND}
  20         sys-devel/bison
  21         sys-devel/flex
  22         virtual/pkgconfig
  23         test? ( dev-libs/check )"
  24 RDEPEND="${CDEPEND}
  25         selinux? ( sec-policy/selinux-radvd )
  26 "
  27 DOCS=( CHANGES README TODO radvd.conf.example )
  28
  29 pkg_setup() {
  30         enewgroup radvd
  31         enewuser radvd -1 -1 /dev/null radvd
  32
  33         # force ownership of radvd user and group (bug #19647)
  34         [[ -d ${ROOT}/var/run/radvd ]] && chown radvd:radvd "${ROOT}"/var/run/radvd
  35 }
  36
  37 src_configure() {
  38         econf --with-pidfile=/var/run/radvd/radvd.pid \
  39                 --disable-silent-rules \
  40                 $(use_with test check)
  41 }
  42
  43 src_install() {
  44         default
  45
  46         dohtml INTRO.html
  47
  48         newinitd "${FILESDIR}"/${PN}-1.9.1.init ${PN}
  49         newconfd "${FILESDIR}"/${PN}.conf ${PN}
  50
  51         systemd_dounit "${FILESDIR}"/${PN}.service
  52         systemd_newtmpfilesd  "${FILESDIR}"/${PN}.tmpfilesd ${PN}.conf
  53
  54         if use kernel_FreeBSD ; then
  55                 sed -i -e \
  56                         's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
  57                         "${D}"/etc/init.d/${PN} || die
  58         fi
  59
  60         readme.gentoo_create_doc
  61 }
  62
  63 DISABLE_AUTOFORMATTING=1
  64 DOC_CONTENTS="Please create a configuratoion ${ROOT}etc/radvd.conf.
  65 See ${ROOT}usr/share/doc/${PF} for an example.
  66
  67 grsecurity users should allow a specific group to read /proc
  68 and add the radvd user to that group, otherwise radvd may
  69 segfault on startup."