net-misc/putty/putty-0.65.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools eutils gnome2-utils toolchain-funcs
   7
   8 DESCRIPTION="A Free Telnet/SSH Client"
   9 HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/putty/"
  10 LICENSE="MIT"
  11
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
  14 IUSE="doc +gtk ipv6 kerberos"
  15 SRC_URI="
  16         https://dev.gentoo.org/~jer/${PN}-icons.tar.bz2
  17         http://the.earth.li/~sgtatham/${PN}/latest/${P}.tar.gz
  18 "
  19
  20 RDEPEND="
  21         !net-misc/pssh
  22         gtk? (
  23                 dev-libs/glib:2
  24                 x11-libs/gdk-pixbuf
  25                 x11-libs/gtk+:2
  26                 x11-libs/libX11
  27                 x11-libs/pango
  28         )
  29         kerberos? ( virtual/krb5 )
  30 "
  31 DEPEND="
  32         ${RDEPEND}
  33         dev-lang/perl
  34         virtual/pkgconfig
  35 "
  36
  37 src_prepare() {
  38         sed -i \
  39                 -e '/AM_PATH_GTK(/d' \
  40                 -e 's|-Werror||g' \
  41                 configure.ac || die
  42
  43         eautoreconf
  44 }
  45
  46 src_configure() {
  47         cd "${S}"/unix || die
  48         econf \
  49                 $(use_with kerberos gssapi) \
  50                 $(use_with gtk)
  51 }
  52
  53 src_compile() {
  54         cd "${S}"/unix || die
  55         emake AR=$(tc-getAR) $(usex ipv6 '' COMPAT=-DNO_IPV6)
  56 }
  57
  58 src_install() {
  59         dodoc doc/puttydoc.txt
  60
  61         if use doc; then
  62                 dohtml doc/*.html
  63         fi
  64
  65         cd "${S}"/unix || die
  66         default
  67
  68         if use gtk ; then
  69                 for i in 16 22 24 32 48 64 128 256; do
  70                         newicon -s ${i} "${WORKDIR}"/${PN}-icons/${PN}-${i}.png ${PN}.png
  71                 done
  72
  73                 # install desktop file provided by Gustav Schaffter in #49577
  74                 make_desktop_entry ${PN} PuTTY ${PN} Network
  75         fi
  76 }
  77
  78 pkg_preinst() {
  79         use gtk && gnome2_icon_savelist
  80 }
  81
  82 pkg_postinst() {
  83         use gtk && gnome2_icon_cache_update
  84 }
  85
  86 pkg_postrm() {
  87         use gtk && gnome2_icon_cache_update
  88 }