net-misc/nx/nx-3.5.0.30.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools eutils multilib readme.gentoo
   7
   8 DESCRIPTION="NX compression technology core libraries"
   9 HOMEPAGE="http://www.x2go.org/doku.php/wiki:libs:nx-libs"
  10
  11 SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~ppc x86"
  16 IUSE="elibc_glibc"
  17
  18 RDEPEND="media-libs/freetype:2
  19         >=media-libs/libpng-1.2.8:*
  20         >=sys-libs/zlib-1.2.3
  21         virtual/jpeg:*"
  22
  23 DEPEND="${RDEPEND}
  24                 x11-libs/libfontenc
  25                 x11-misc/gccmakedep
  26                 x11-misc/imake
  27                 x11-proto/inputproto"
  28
  29 S=${WORKDIR}/nx-libs-${PV}
  30
  31 DOC_CONTENTS="If you get problems with rendering gtk+ apps, enable the xlib-xcb
  32 useflag on x11-libs/cairo."
  33
  34 src_prepare() {
  35         # For nxcl/qtnx
  36         cd "${S}"/nxproxy
  37         epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch
  38
  39         cd "${S}"
  40         # -fPIC
  41         epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
  42         # Drop force -O3, set AR/RANLIB
  43         epatch "${FILESDIR}"/${PN}-3.5.0.17-cflags_ar_ranlib.patch
  44         # Fix libX11 underlinking, #546868
  45         epatch "${FILESDIR}"/${P}-fix_X11_underlinking.patch
  46
  47         # run autoreconf in all neeed folders
  48         for i in nxcomp nxcompext nxcompshad nxproxy; do
  49                 cd "${S}"/${i}
  50                 eautoreconf ${i}
  51                 cd "${S}"
  52         done
  53
  54         # From xorg-x11-6.9.0-r3.ebuild
  55         cd "${S}/nx-X11"
  56         HOSTCONF="config/cf/host.def"
  57         echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
  58         echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
  59         echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
  60         # Respect LDFLAGS
  61         echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
  62         echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
  63 }
  64
  65 src_configure() {
  66         cd "${S}"/nxproxy
  67         econf
  68 }
  69
  70 src_compile() {
  71         cd "${S}/nx-X11"
  72         FAST=1 emake World WORLDOPTS="" MAKE="make" \
  73                 AR="$(tc-getAR) clq" RANLIB="$(tc-getRANLIB)" \
  74                 CC="$(tc-getCC)" CXX="$(tc-getCXX)"
  75
  76         cd "${S}"/nxproxy
  77         emake
  78 }
  79
  80 src_install() {
  81         NX_ROOT=/usr/$(get_libdir)/NX
  82
  83         for x in nxagent nxauth nxproxy; do
  84                 make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
  85                         die " $x wrapper creation failed"
  86         done
  87
  88         into ${NX_ROOT}
  89         dobin "${S}"/nx-X11/programs/Xserver/nxagent
  90         dobin "${S}"/nx-X11/programs/nxauth/nxauth
  91         dobin "${S}"/nxproxy/nxproxy
  92
  93         for lib in X11 Xau Xcomposite Xdamage Xdmcp Xext Xfixes Xinerama Xpm Xrandr Xrender Xtst;
  94         do
  95                 dolib.so "${S}"/nx-X11/lib/${lib}/libNX_${lib}.so*
  96         done
  97
  98         dolib.so "${S}"/nxcomp/libXcomp.so*
  99         dolib.so "${S}"/nxcompext/libXcompext.so*
 100         dolib.so "${S}"/nxcompshad/libXcompshad.so*
 101
 102         insinto /etc/nxagent
 103         newins etc/keystrokes.cfg keystroke.cfg
 104         doicon nx-X11/programs/Xserver/hw/nxagent/x2go.xpm
 105
 106         readme.gentoo_create_doc
 107 }