net-misc/netkit-timed/netkit-timed-0.17-r10.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit flag-o-matic toolchain-funcs
   7
   8 IUSE=""
   9 DESCRIPTION="Netkit - timed"
  10 SRC_URI="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/${P}.tar.gz"
  11 HOMEPAGE="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/"
  12 KEYWORDS="amd64 ~mips ppc ppc64 sparc x86"
  13 LICENSE="BSD GPL-2"
  14 SLOT="0"
  15
  16 DEPEND=""
  17 RDEPEND=""
  18
  19 src_prepare() {
  20         eapply "${FILESDIR}"/0.17-CFLAG-DEF-fix.patch
  21         eapply "${FILESDIR}"/0.17-timed-opt-parsing.patch
  22         sed -i configure \
  23                 -e '/^LDFLAGS=/d' \
  24                 || die "sed configure"
  25         default
  26 }
  27
  28 src_configure() {
  29         # Note this is not an autoconf configure script. econf fails
  30         append-flags -DCLK_TCK=CLOCKS_PER_SEC
  31         ./configure --prefix=/usr --with-c-compiler=$(tc-getCC) || die "bad configure"
  32 }
  33
  34 src_install() {
  35         dosbin timed/timed/timed
  36         doman  timed/timed/timed.8
  37         dosbin timed/timedc/timedc
  38         doman  timed/timedc/timedc.8
  39         dodoc  README ChangeLog BUGS
  40
  41         newinitd "${FILESDIR}"/timed.rc6 timed
  42 }