net-misc/mico/mico-2.3.13-r7.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="3"
   6
   7 inherit eutils flag-o-matic toolchain-funcs autotools
   8
   9 DESCRIPTION="A freely available and fully compliant implementation of the CORBA standard"
  10 HOMEPAGE="http://www.mico.org/"
  11 SRC_URI="http://www.mico.org/${P}.tar.gz"
  12
  13 PATCH_VER=0.3
  14
  15 LICENSE="GPL-2 LGPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~ppc-aix ~ia64-hpux ~amd64-linux ~x86-linux ~sparc-solaris ~x86-winnt"
  18 IUSE="gtk postgres qt4 ssl tcl threads X"
  19 RESTRICT="test" #298101
  20
  21 [[ -z ${PATCH_VER} ]] || \
  22         SRC_URI="${SRC_URI} https://dev.gentoo.org/~haubi/distfiles/${P}-gentoo-patches-${PATCH_VER}.tar.bz2"
  23
  24 # doesn't compile:
  25 #   bluetooth? ( net-wireless/bluez )
  26
  27 RDEPEND="
  28         gtk?       ( x11-libs/gtk+:2 )
  29         postgres?  ( dev-db/postgresql )
  30         qt4?       ( dev-qt/qtgui:4[qt3support] )
  31         ssl?       ( dev-libs/openssl )
  32         tcl?       ( dev-lang/tcl:0 )
  33         X?         ( x11-libs/libXt )
  34 "
  35 DEPEND="${RDEPEND}
  36         >=sys-devel/flex-2.5.2
  37         >=sys-devel/bison-1.22
  38 "
  39
  40 S=${WORKDIR}/${PN}
  41
  42 src_prepare() {
  43         EPATCH_SUFFIX=patch epatch "${WORKDIR}"/patches
  44
  45         eautoreconf
  46
  47         # cannot use big TOC (AIX only), gdb doesn't like it.
  48         # This assumes that the compiler (or -wrapper) uses
  49         # gcc flag '-mminimal-toc' for compilation.
  50         sed -i -e 's/,-bbigtoc//' "${S}"/configure
  51
  52         if use qt4; then
  53                 sed -i -e "s, -lqt\", $(pkg-config --libs Qt3Support)\"," configure ||
  54                         die "cannot update to use Qt3Support of qt4"
  55         fi
  56 }
  57
  58 src_configure() {
  59         tc-export CC CXX
  60
  61         if use gtk; then
  62                 # need gtk-1 wrapper for gtk-2
  63                 export PATH="${WORKDIR}"/helpers:${PATH}
  64         fi
  65
  66         # Don't know which version of JavaCUP would suffice, but there is no
  67         # configure argument to disable checking for JavaCUP.
  68         # So we override the configure check to not find 'javac'.
  69         export ac_cv_path_JAVAC=no
  70
  71         # '--without-ssl' just does not add another search path - the only way
  72         # to disable openssl utilization seems to override the configure check.
  73         use ssl || export ac_cv_lib_ssl_open=no
  74
  75         # CFLAGS aren't used when checking for <qapplication.h>, but CPPFLAGS are.
  76         use qt4 && append-cppflags $(pkg-config --cflags Qt3Support)
  77
  78         local myconf=
  79         myconf() {
  80                 myconf="${myconf} $*"
  81         }
  82
  83         myconf --disable-mini-stl
  84         myconf $(use_enable threads)
  85
  86         # '--without-*' or '--with-*=no' does not disable some features,
  87         # the value needs to be empty instead.
  88         # This applies to: gtk, pgsql, qt, tcl, bluetooth.
  89         myconf --with-gtk=$(  use gtk      && echo "${EPREFIX}"/usr)
  90         myconf --with-pgsql=$(use postgres && echo "${EPREFIX}"/usr)
  91         myconf --with-qt=$(   use qt4      && echo "${EPREFIX}"/usr)
  92         myconf --with-tcl=$(  use tcl      && echo "${EPREFIX}"/usr)
  93         # bluetooth and wireless both don't compile cleanly
  94         myconf --with-bluetooth=''
  95         myconf --disable-wireless
  96         # But --without-x works.
  97         myconf $(use_with X x "${EPREFIX}"/usr)
  98
  99         # http://www.mico.org/pipermail/mico-devel/2009-April/010285.html
 100         [[ ${CHOST} == *-hpux* ]] && append-cppflags -D_XOPEN_SOURCE_EXTENDED
 101
 102         if [[ ${CHOST} == *-winnt* ]]; then
 103                 # disabling static libs, since ar on interix takes nearly
 104                 # one hour per library, thanks to mico's monster objects.
 105                 use threads &&
 106                 ewarn "disabling USE='threads', does not work on ${CHOST}"
 107                 myconf --disable-threads --disable-static --enable-final
 108                 append-flags -D__STDC__
 109         fi
 110
 111         econf ${myconf}
 112 }
 113
 114 src_install() {
 115         emake INSTDIR="${ED}"usr SHARED_INSTDIR="${ED}"usr install LDCONFIG=: || die "install failed"
 116         if [[ $(get_libdir) != lib ]]; then #500744
 117                 mv "${ED}"usr/lib "${ED}"usr/$(get_libdir) || die
 118         fi
 119
 120         dodir /usr/share || die
 121         mv "${ED}"usr/man "${ED}"usr/share || die
 122         dodir /usr/share/doc/${PF} || die
 123         mv "${ED}"usr/doc "${ED}"usr/share/doc/${PF} || die
 124
 125         dodoc BUGS CHANGES* CONVERT FAQ README* ROADMAP TODO VERSION WTODO || die
 126 }