net-misc/memcached/memcached-1.5.3-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils flag-o-matic systemd user
   6
   7 MY_PV="${PV/_rc/-rc}"
   8 MY_P="${PN}-${MY_PV}"
   9
  10 DESCRIPTION="High-performance, distributed memory object caching system"
  11 HOMEPAGE="http://memcached.org/"
  12 SRC_URI="https://www.memcached.org/files/${MY_P}.tar.gz
  13                  https://www.memcached.org/files/old/${MY_P}.tar.gz"
  14
  15 LICENSE="BSD"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  18 IUSE="debug sasl seccomp selinux slabs-reassign test" # hugetlbfs later
  19
  20 RDEPEND=">=dev-libs/libevent-1.4:=
  21                  dev-lang/perl
  22                  sasl? ( dev-libs/cyrus-sasl )
  23                  seccomp? ( sys-libs/libseccomp )
  24                  selinux? ( sec-policy/selinux-memcached )"
  25 DEPEND="${RDEPEND}
  26                 test? ( virtual/perl-Test-Harness >=dev-perl/Cache-Memcached-1.24 )"
  27
  28 S="${WORKDIR}/${MY_P}"
  29
  30 src_prepare() {
  31         epatch "${FILESDIR}/${PN}-1.2.2-fbsd.patch"
  32         epatch "${FILESDIR}/${PN}-1.4.0-fix-as-needed-linking.patch"
  33         epatch "${FILESDIR}/${PN}-1.4.4-as-needed.patch"
  34         epatch "${FILESDIR}/${PN}-1.4.17-EWOULDBLOCK.patch"
  35         sed -i -e 's,-Werror,,g' configure.ac || die
  36         sed -i -e 's,AM_CONFIG_HEADER,AC_CONFIG_HEADERS,' configure.ac || die
  37         eautoreconf
  38         use slabs-reassign && append-flags -DALLOW_SLABS_REASSIGN
  39
  40         # Tweak upstream systemd unit to use Gentoo variables/envfile.
  41         # As noted by bug #587440
  42         sed -i -e '/^ExecStart/{
  43                         s,{USER},{MEMCACHED_RUNAS},g;
  44                         s,{CACHESIZE},{MEMUSAGE},g;
  45                         s,OPTIONS,MISC_OPTS,g;
  46                 };
  47                 /Environment=/{s,OPTIONS,MISC_OPTS,g;};
  48                 /EnvironmentFile=/{s,/sysconfig/,/conf.d/,g;};
  49                 ' \
  50                 "${S}"/scripts/memcached.service
  51         default
  52 }
  53
  54 src_configure() {
  55         econf \
  56                 --disable-docs \
  57                 $(use_enable sasl)
  58         # The xml2rfc tool to build the additional docs requires TCL :-(
  59         # `use_enable doc docs`
  60 }
  61
  62 src_compile() {
  63         # There is a heavy degree of per-object compile flags
  64         # Users do NOT know better than upstream. Trying to compile the testapp and
  65         # the -debug version with -DNDEBUG _WILL_ fail.
  66         append-flags -UNDEBUG -pthread
  67         emake testapp memcached-debug CFLAGS="${CFLAGS}"
  68         filter-flags -UNDEBUG
  69         emake
  70 }
  71
  72 src_install() {
  73         emake DESTDIR="${D}" install
  74         dobin scripts/memcached-tool
  75         use debug && dobin memcached-debug
  76
  77         dodoc AUTHORS ChangeLog NEWS README.md doc/{CONTRIBUTORS,*.txt}
  78
  79         newconfd "${FILESDIR}/memcached.confd" memcached
  80         newinitd "${FILESDIR}/memcached.init2" memcached
  81         systemd_dounit "${S}/scripts/memcached.service"
  82 }
  83
  84 pkg_postinst() {
  85         enewuser memcached -1 -1 /dev/null daemon
  86
  87         elog "With this version of Memcached Gentoo now supports multiple instances."
  88         elog "To enable this you should create a symlink in /etc/init.d/ for each instance"
  89         elog "to /etc/init.d/memcached and create the matching conf files in /etc/conf.d/"
  90         elog "Please see Gentoo bug #122246 for more info"
  91 }
  92
  93 src_test() {
  94         emake -j1 test
  95 }