net-misc/memcached/memcached-1.5.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils flag-o-matic systemd user
   6
   7 MY_PV="${PV/_rc/-rc}"
   8 MY_P="${PN}-${MY_PV}"
   9
  10 DESCRIPTION="High-performance, distributed memory object caching system"
  11 HOMEPAGE="http://memcached.org/"
  12 SRC_URI="https://www.memcached.org/files/${MY_P}.tar.gz
  13                  https://www.memcached.org/files/old/${MY_P}.tar.gz"
  14
  15 LICENSE="BSD"
  16 SLOT="0"
  17 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ia64 ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  18 IUSE="test slabs-reassign debug sasl selinux" # hugetlbfs later
  19
  20 RDEPEND=">=dev-libs/libevent-1.4:=
  21                  dev-lang/perl
  22                  sasl? ( dev-libs/cyrus-sasl )
  23                  selinux? ( sec-policy/selinux-memcached )"
  24 DEPEND="${RDEPEND}
  25                 test? ( virtual/perl-Test-Harness >=dev-perl/Cache-Memcached-1.24 )"
  26
  27 S="${WORKDIR}/${MY_P}"
  28
  29 src_prepare() {
  30         epatch "${FILESDIR}/${PN}-1.2.2-fbsd.patch"
  31         epatch "${FILESDIR}/${PN}-1.4.0-fix-as-needed-linking.patch"
  32         epatch "${FILESDIR}/${PN}-1.4.4-as-needed.patch"
  33         epatch "${FILESDIR}/${PN}-1.4.17-EWOULDBLOCK.patch"
  34         sed -i -e 's,-Werror,,g' configure.ac || die
  35         sed -i -e 's,AM_CONFIG_HEADER,AC_CONFIG_HEADERS,' configure.ac || die
  36         eautoreconf
  37         use slabs-reassign && append-flags -DALLOW_SLABS_REASSIGN
  38
  39         # Tweak upstream systemd unit to use Gentoo variables/envfile.
  40         # As noted by bug #587440
  41         sed -i -e '/^ExecStart/{
  42                         s,{USER},{MEMCACHED_RUNAS},g;
  43                         s,{CACHESIZE},{MEMUSAGE},g;
  44                         s,OPTIONS,MISC_OPTS,g;
  45                 };
  46                 /Environment=/{s,OPTIONS,MISC_OPTS,g;};
  47                 /EnvironmentFile=/{s,/sysconfig/,/conf.d/,g;};
  48                 ' \
  49                 "${S}"/scripts/memcached.service
  50         default
  51 }
  52
  53 src_configure() {
  54         econf \
  55                 --disable-docs \
  56                 $(use_enable sasl)
  57         # The xml2rfc tool to build the additional docs requires TCL :-(
  58         # `use_enable doc docs`
  59 }
  60
  61 src_compile() {
  62         # There is a heavy degree of per-object compile flags
  63         # Users do NOT know better than upstream. Trying to compile the testapp and
  64         # the -debug version with -DNDEBUG _WILL_ fail.
  65         append-flags -UNDEBUG -pthread
  66         emake testapp memcached-debug CFLAGS="${CFLAGS}"
  67         filter-flags -UNDEBUG
  68         emake
  69 }
  70
  71 src_install() {
  72         emake DESTDIR="${D}" install
  73         dobin scripts/memcached-tool
  74         use debug && dobin memcached-debug
  75
  76         dodoc AUTHORS ChangeLog NEWS README.md doc/{CONTRIBUTORS,*.txt}
  77
  78         newconfd "${FILESDIR}/memcached.confd" memcached
  79         newinitd "${FILESDIR}/memcached.init2" memcached
  80         systemd_dounit "${S}/scripts/memcached.service"
  81 }
  82
  83 pkg_postinst() {
  84         enewuser memcached -1 -1 /dev/null daemon
  85
  86         elog "With this version of Memcached Gentoo now supports multiple instances."
  87         elog "To enable this you should create a symlink in /etc/init.d/ for each instance"
  88         elog "to /etc/init.d/memcached and create the matching conf files in /etc/conf.d/"
  89         elog "Please see Gentoo bug #122246 for more info"
  90 }
  91
  92 src_test() {
  93         emake -j1 test
  94 }