net-misc/freerdp/freerdp-2.0.0_pre20161219.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit cmake-utils
   7
   8 if [[ ${PV} != 9999 ]]; then
   9         COMMIT="8d0809cf26868fc5ff651850a32724650597747f"
  10         SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  11         KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
  12         S="${WORKDIR}/FreeRDP-${COMMIT}"
  13 else
  14         inherit git-r3
  15         SRC_URI=""
  16         EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
  17 fi
  18
  19 DESCRIPTION="Free implementation of the Remote Desktop Protocol"
  20 HOMEPAGE="http://www.freerdp.com/"
  21
  22 LICENSE="Apache-2.0"
  23 SLOT="0/2"
  24 IUSE="alsa +client cpu_flags_x86_sse2 cups debug doc ffmpeg gstreamer jpeg libav libressl neon pulseaudio server smartcard systemd test usb wayland X xinerama xv"
  25
  26 RDEPEND="
  27         !libressl? ( dev-libs/openssl:0= )
  28         libressl? ( dev-libs/libressl:0= )
  29         sys-libs/zlib:0
  30         alsa? ( media-libs/alsa-lib )
  31         cups? ( net-print/cups )
  32         client? (
  33                 usb? (
  34                         virtual/libudev:0=
  35                         sys-apps/util-linux:0=
  36                         dev-libs/dbus-glib:0=
  37                         virtual/libusb:1=
  38                 )
  39                 X? (
  40                         x11-libs/libXcursor
  41                         x11-libs/libXext
  42                         x11-libs/libXi
  43                         x11-libs/libXrender
  44                         xinerama? ( x11-libs/libXinerama )
  45                         xv? ( x11-libs/libXv )
  46                 )
  47         )
  48         ffmpeg? (
  49                 libav? ( media-video/libav:0= )
  50                 !libav? ( media-video/ffmpeg:0= )
  51         )
  52         gstreamer? (
  53                 media-libs/gstreamer:1.0
  54                 media-libs/gst-plugins-base:1.0
  55                 x11-libs/libXrandr
  56         )
  57         jpeg? ( virtual/jpeg:0 )
  58         pulseaudio? ( media-sound/pulseaudio )
  59         server? (
  60                 X? (
  61                         x11-libs/libXcursor
  62                         x11-libs/libXdamage
  63                         x11-libs/libXext
  64                         x11-libs/libXfixes
  65                         x11-libs/libXrandr
  66                         x11-libs/libXtst
  67                         xinerama? ( x11-libs/libXinerama )
  68                 )
  69         )
  70         smartcard? ( sys-apps/pcsc-lite )
  71         systemd? ( sys-apps/systemd:0= )
  72         wayland? (
  73                 dev-libs/wayland
  74                 x11-libs/libxkbcommon
  75         )
  76         X? (
  77                 x11-libs/libX11
  78                 x11-libs/libxkbfile
  79         )
  80 "
  81 DEPEND="${RDEPEND}
  82         virtual/pkgconfig
  83         client? ( X? ( doc? (
  84                 app-text/docbook-xml-dtd:4.1.2
  85                 app-text/xmlto
  86         ) ) )
  87 "
  88
  89 DOCS=( README )
  90
  91 PATCHES=(
  92         "${FILESDIR}"/freerdp-libressl.patch
  93 )
  94
  95 src_configure() {
  96         local mycmakeargs=(
  97                 -DWITH_ALSA=$(usex alsa)
  98                 -DWITH_CLIENT=$(usex client)
  99                 -DWITH_CUPS=$(usex cups)
 100                 -DWITH_DEBUG_ALL=$(usex debug)
 101                 -DWITH_MANPAGES=$(usex doc)
 102                 -DWITH_FFMPEG=$(usex ffmpeg)
 103                 -DWITH_GSTREAMER_1_0=$(usex gstreamer)
 104                 -DWITH_JPEG=$(usex jpeg)
 105                 -DWITH_NEON=$(usex neon)
 106                 -DWITH_PULSE=$(usex pulseaudio)
 107                 -DWITH_SERVER=$(usex server)
 108                 -DWITH_PCSC=$(usex smartcard)
 109                 -DWITH_LIBSYSTEMD=$(usex systemd)
 110                 -DWITH_SSE2=$(usex cpu_flags_x86_sse2)
 111                 -DCHANNEL_URBDRC=$(usex usb)
 112                 -DWITH_X11=$(usex X)
 113                 -DWITH_XINERAMA=$(usex xinerama)
 114                 -DWITH_XV=$(usex xv)
 115                 -DBUILD_TESTING=$(usex test)
 116                 -DWITH_WAYLAND=$(usex wayland)
 117         )
 118         cmake-utils_src_configure
 119 }