net-misc/connman/connman-1.32.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="6"
   6 inherit systemd
   7
   8 DESCRIPTION="Provides a daemon for managing internet connections"
   9 HOMEPAGE="https://01.org/connman"
  10 SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
  15 IUSE="bluetooth debug doc examples +ethernet l2tp ofono openvpn openconnect pptp policykit tools vpnc +wifi wispr"
  16
  17 RDEPEND=">=dev-libs/glib-2.16
  18         >=sys-apps/dbus-1.2.24
  19         >=net-firewall/iptables-1.4.8
  20         bluetooth? ( net-wireless/bluez )
  21         l2tp? ( net-dialup/xl2tpd )
  22         ofono? ( net-misc/ofono )
  23         openconnect? ( net-misc/openconnect )
  24         openvpn? ( net-misc/openvpn )
  25         policykit? ( sys-auth/polkit )
  26         pptp? ( net-dialup/pptpclient )
  27         vpnc? ( net-misc/vpnc )
  28         wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
  29         wispr? ( net-libs/gnutls )"
  30
  31 DEPEND="${RDEPEND}
  32         >=sys-kernel/linux-headers-2.6.39"
  33
  34 PATCHES=(
  35         "${FILESDIR}/${PN}-1.32-execinfo-assumptions.patch"
  36         "${FILESDIR}/${PN}-1.31-xtables.patch"
  37 )
  38
  39 src_configure() {
  40         econf \
  41                 --localstatedir=/var \
  42                 --enable-client \
  43                 --enable-datafiles \
  44                 --enable-loopback=builtin \
  45                 $(use_enable examples test) \
  46                 $(use_enable ethernet ethernet builtin) \
  47                 $(use_enable wifi wifi builtin) \
  48                 $(use_enable bluetooth bluetooth builtin) \
  49                 $(use_enable l2tp l2tp builtin) \
  50                 $(use_enable ofono ofono builtin) \
  51                 $(use_enable openconnect openconnect builtin) \
  52                 $(use_enable openvpn openvpn builtin) \
  53                 $(use_enable policykit polkit builtin) \
  54                 $(use_enable pptp pptp builtin) \
  55                 $(use_enable vpnc vpnc builtin) \
  56                 $(use_enable wispr wispr builtin) \
  57                 $(use_enable debug) \
  58                 $(use_enable tools) \
  59                 --disable-iospm \
  60                 --disable-hh2serial-gps
  61 }
  62
  63 src_install() {
  64         default
  65         dobin client/connmanctl
  66
  67         if use doc; then
  68                 dodoc doc/*.txt
  69         fi
  70         keepdir /var/lib/${PN}
  71         newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
  72         newconfd "${FILESDIR}"/${PN}.confd ${PN}
  73 }