net-mail/qmailanalog/qmailanalog-0.70-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit fixheadtails toolchain-funcs
   7
   8 DESCRIPTION="collection of tools to help you analyze qmail's activity record"
   9 SRC_URI="http://cr.yp.to/software/${P}.tar.gz"
  10 HOMEPAGE="http://cr.yp.to/qmailanalog.html"
  11
  12 LICENSE="freedist public-domain" # public-domain for files/tai64nfrac.c
  13 SLOT="0"
  14 KEYWORDS="~amd64 sparc x86"
  15 IUSE=""
  16
  17 DEPEND="sys-apps/groff"
  18
  19 src_prepare() {
  20         eapply_user
  21         eapply "${FILESDIR}"/${PV}-errno.patch
  22         ht_fix_file auto_home.c.do default.do Makefile
  23 }
  24
  25 src_configure() {
  26         echo "/var/qmail" > conf-home || die
  27         echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
  28         echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
  29 }
  30
  31 src_compile() {
  32         default
  33         $(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} \
  34                 "${FILESDIR}"/tai64nfrac.c -o tai64nfrac || die
  35 }
  36
  37 src_test() { :; }
  38
  39 src_install() {
  40         doman matchup.1 xqp.1 xsender.1 xrecipient.1 columnt.1
  41         dodoc MATCHUP ACCOUNTING BLURB
  42
  43         exeopts -o root -g qmail -m 755
  44         exeinto /var/qmail/bin
  45         doexe columnt ddist deferrals failures matchup recipients rhosts
  46         doexe rxdelay senders successes suids xqp xrecipient xsender
  47         doexe zddist zdeferrals zfailures zoverall zrecipients zrhosts
  48         doexe zrxdelay zsenders zsendmail zsuccesses zsuids tai64nfrac
  49 }