net-mail/qmailadmin/qmailadmin-1.2.15-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit qmail webapp autotools
   7
   8 MY_P=${P/_rc/-rc}
   9
  10 DESCRIPTION="A web interface for managing a qmail system with virtual domains"
  11 HOMEPAGE="http://www.inter7.com/qmailadmin.html"
  12 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 WEBAPP_MANUAL_SLOT="yes"
  17 KEYWORDS="amd64 arm ~hppa ~ia64 ppc s390 sparc x86"
  18 IUSE="maildrop"
  19 # the RESTRICT is because the vpopmail lib directory is locked down
  20 # and non-root can't access them.
  21 RESTRICT="userpriv"
  22
  23 RDEPEND="virtual/qmail
  24         >=net-mail/vpopmail-5.4.33
  25         net-mail/autorespond
  26         maildrop? ( >=mail-filter/maildrop-2.0.1 )"
  27 DEPEND=${RDEPEND}
  28
  29 S="${WORKDIR}"/${MY_P}
  30
  31 src_prepare() {
  32         eapply "${FILESDIR}"/${PN}-1.2.9-maildir.patch
  33         eapply "${FILESDIR}"/${PN}-1.2.12-quota-overflow.patch
  34         eapply "${FILESDIR}"/${PN}-1.2.15-quota-security.patch
  35         eapply_user
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         # Pass spam stuff through $@ so we get the quoting right
  41         if use maildrop ; then
  42                 set -- --enable-modify-spam \
  43                         --enable-spam-command='|preline maildrop /etc/maildroprc'
  44         else
  45                 set --
  46         fi
  47
  48         econf \
  49                 --enable-valias \
  50                 --enable-vpopmaildir=/var/vpopmail \
  51                 --enable-htmldir="${MY_HTDOCSDIR}" \
  52                 --enable-imagedir="${MY_HTDOCSDIR}"/images \
  53                 --enable-imageurl=/${PN}/images \
  54                 --enable-htmllibdir=/usr/share/${PN}/htmllib \
  55                 --enable-cgibindir="${MY_CGIBINDIR}" \
  56                 --enable-cgipath=/cgi-bin/${PN} \
  57                 --enable-qmaildir="${QMAIL_HOME}" \
  58                 --enable-autoresponder-path="${QMAIL_HOME}"/bin \
  59                 --enable-true-path=/bin \
  60                 --enable-ezmlmdir=/usr/bin \
  61                 --enable-domain-autofill \
  62                 --enable-modify-quota \
  63                 --enable-no-cache \
  64                 --enable-trivial-password \
  65                 --enable-catchall \
  66                 --enable-maxusersperpage=50 \
  67                 --enable-maxaliasesperpage=50 \
  68                 --enable-vpopuser=vpopmail \
  69                 --enable-vpopgroup=vpopmail \
  70                 "$@"
  71 }
  72
  73 src_install() {
  74         webapp_src_preinst
  75
  76         local DOCS=(
  77                 AUTHORS INSTALL README.hooks BUGS TODO ChangeLog TRANSLATORS
  78                 NEWS FAQ README contrib/*
  79         )
  80         default
  81
  82         webapp_src_install
  83 }
  84
  85 pkg_postinst() {
  86         einfo "If you would like support for ezmlm mailing lists inside qmailadmin,"
  87         einfo "please emerge some variant of ezmlm-idx."
  88         webapp_pkg_postinst
  89 }