net-mail/postfix-logwatch/postfix-logwatch-1.40.03-r3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="A log analyzer for postfix"
   7 HOMEPAGE="http://logreporters.sourceforge.net/"
   8 SRC_URI="mirror://sourceforge/logreporters/${P}.tgz"
   9
  10 LICENSE="MIT"
  11 SLOT="0"
  12 KEYWORDS="amd64 x86"
  13
  14 RDEPEND="dev-lang/perl"
  15
  16 PATCHES=(
  17         "${FILESDIR}/unescaped-left-brace.patch"
  18         "${FILESDIR}/redundant-argument-to-sprintf.patch"
  19         "${FILESDIR}/multi-digit-enhanced-status.patch"
  20         "${FILESDIR}/all-server-ports-busy-lines.patch"
  21 )
  22
  23 src_prepare() {
  24         default
  25         # Replace the default config file location with ours.
  26         local cfg_default='/usr/local/etc/${progname_prefix}-logwatch.conf'
  27         local cfg_gentoo='/etc/${progname_prefix}-logwatch.conf';
  28         sed -i "s~${cfg_default}~${cfg_gentoo}~" ${PN} \
  29                 || die 'failed to update the default config location'
  30 }
  31
  32 src_compile() {
  33         # The default make target just outputs instructions. We don't want
  34         # the user to see these, so we avoid the default emake.
  35         :
  36 }
  37
  38 src_install() {
  39         dodoc Bugs Changes README ${PN}.conf-topn
  40         doman ${PN}.1
  41         dobin ${PN}
  42         insinto /etc
  43         doins ${PN}.conf
  44 }