net-mail/mailbase/mailbase-1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 inherit pam eutils user
   5
   6 DESCRIPTION="MTA layout package"
   7 SRC_URI=""
   8 HOMEPAGE="https://www.gentoo.org/"
   9
  10 LICENSE="GPL-2"
  11 SLOT="0"
  12 KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd"
  13 IUSE="pam"
  14
  15 RDEPEND="pam? ( virtual/pam )"
  16
  17 S=${WORKDIR}
  18
  19 pkg_setup() {
  20         enewgroup mail 12
  21         enewuser mail 8 -1 /var/spool/mail mail
  22         enewuser postmaster 14 -1 /var/spool/mail
  23 }
  24
  25 src_install() {
  26         dodir /etc/mail
  27         insinto /etc/mail
  28         doins "${FILESDIR}"/aliases || die
  29         insinto /etc
  30         doins "${FILESDIR}"/mailcap || die
  31
  32         keepdir /var/spool/mail
  33         fowners root:mail /var/spool/mail
  34         fperms 0775 /var/spool/mail
  35         dosym /var/spool/mail /var/mail
  36
  37         newpamd "${FILESDIR}"/common-pamd-include pop
  38         newpamd "${FILESDIR}"/common-pamd-include imap
  39         if use pam ; then
  40                 local p
  41                 for p in pop3 pop3s pops ; do
  42                         dosym pop /etc/pam.d/${p} || die
  43                 done
  44                 for p in imap4 imap4s imaps ; do
  45                         dosym imap /etc/pam.d/${p} || die
  46                 done
  47         fi
  48 }
  49
  50 get_permissions_oct() {
  51         if [[ ${USERLAND} = GNU ]] ; then
  52                 stat -c%a "${ROOT}$1"
  53         elif [[ ${USERLAND} = BSD ]] ; then
  54                 stat -f%p "${ROOT}$1" | cut -c 3-
  55         fi
  56 }
  57
  58 pkg_postinst() {
  59         if [[ "$(get_permissions_oct /var/spool/mail)" != "775" ]] ; then
  60                 echo
  61                 ewarn "Your ${ROOT}/var/spool/mail/ directory permissions differ from"
  62                 ewarn "  those which mailbase set when you first installed it (0775)."
  63                 ewarn "  If you did not change them on purpose, consider running:"
  64                 ewarn
  65                 ewarn "    chmod 0775 ${ROOT}/var/spool/mail/"
  66                 echo
  67         fi
  68 }