net-mail/lbdb/lbdb-0.47.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P=${P/-/_}
   7 DESCRIPTION="Little Brother database"
   8 HOMEPAGE="https://www.spinnaker.de/lbdb/"
   9 SRC_URI="https://www.spinnaker.de/lbdb/download/${MY_P}.tar.gz"
  10
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~ppc ~x86"
  13 LICENSE="GPL-2"
  14 IUSE="abook bbdb crypt evo finger ldap pda test"
  15 RESTRICT="!test? ( test )"
  16
  17 CDEPEND="dev-libs/libvformat
  18         evo? ( mail-client/evolution )
  19         finger? ( net-misc/netkit-fingerd )
  20         abook? ( app-misc/abook )
  21         crypt? ( app-crypt/gnupg )"
  22 DEPEND="${CDEPEND}
  23         test? (
  24                 dev-perl/Palm
  25                 dev-perl/perl-ldap
  26         )"
  27 RDEPEND="${CDEPEND}
  28         bbdb? ( app-emacs/bbdb )
  29         pda? ( dev-perl/Palm )
  30         ldap? ( dev-perl/perl-ldap )"
  31
  32 src_configure() {
  33         local evoversion
  34         local evolution_addressbook_export
  35
  36         if use evo ; then
  37                 evoversion=$(best_version mail-client/evolution)
  38                 evoversion=${evoversion##mail-client/evolution-}
  39                 evolution_addressbook_export="${EPREFIX}/usr/libexec/evolution/$(ver_cut 1-2 ${evoversion})/evolution-addressbook-export"
  40         fi
  41
  42         econf $(use_with finger) \
  43                 $(use_with abook) \
  44                 --without-ypcat \
  45                 $(use_with crypt gpg) \
  46                 $(use_with evo evolution-addressbook-export "${evolution_addressbook_export}" ) \
  47                 --enable-lbdb-dotlock \
  48                 --without-pgpk --without-pgp \
  49                 --without-niscat --without-addr-email --with-getent \
  50                 --libdir="${EPREFIX}"/usr/$(get_libdir)/lbdb
  51 }
  52
  53 src_install() {
  54         emake install_prefix="${D}" install
  55         dodoc README TODO debian/changelog
  56 }