net-mail/amavis-logwatch/amavis-logwatch-1.51.03-r5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="A log analyzer for amavisd-new"
   7 HOMEPAGE="http://logreporters.sourceforge.net/"
   8 SRC_URI="mirror://sourceforge/logreporters/${P}.tgz"
   9
  10 LICENSE="MIT"
  11 SLOT="0"
  12 KEYWORDS="amd64 x86"
  13
  14 RDEPEND="dev-lang/perl"
  15
  16 PATCHES=(
  17         "${FILESDIR}/unescaped-left-brace.patch"
  18         "${FILESDIR}/redundant-argument-to-sprintf.patch"
  19         "${FILESDIR}/ignore-amavis-startup-notifications.patch"
  20         "${FILESDIR}/ignore-utf8smtp-lines.patch"
  21         "${FILESDIR}/unchecked-encrypted.patch"
  22         "${FILESDIR}/file-libmagic-errors.patch"
  23         "${FILESDIR}/ignore-all-sd_notify-lines.patch"
  24         "${FILESDIR}/no-pid_file-configured.patch"
  25         "${FILESDIR}/will-bind-to-lines.patch"
  26         "${FILESDIR}/SANITIZED-NULL-bytes-messages.patch"
  27         "${FILESDIR}/handle-clamd-select-failed.patch"
  28 )
  29
  30 src_prepare() {
  31         default
  32         # Replace the default config file location with ours.
  33         local cfg_default='/usr/local/etc/${progname_prefix}-logwatch.conf'
  34         local cfg_gentoo='/etc/${progname_prefix}-logwatch.conf';
  35         sed -i "s~${cfg_default}~${cfg_gentoo}~" ${PN} \
  36                 || die 'failed to update the default config location'
  37 }
  38
  39 src_compile() {
  40         # The default make target just outputs instructions. We don't want
  41         # the user to see these, so we avoid the default emake.
  42         :
  43 }
  44
  45 src_install() {
  46         dodoc Bugs Changes README
  47         doman ${PN}.1
  48         dobin ${PN}
  49         insinto /etc
  50         doins ${PN}.conf
  51 }