net-mail/amavis-logwatch/amavis-logwatch-1.51.03-r3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DESCRIPTION="A log analyzer for amavisd-new"
   7 HOMEPAGE="http://logreporters.sourceforge.net/"
   8 SRC_URI="mirror://sourceforge/logreporters/${P}.tgz"
   9
  10 LICENSE="MIT"
  11 SLOT="0"
  12 KEYWORDS="amd64 x86"
  13
  14 RDEPEND="dev-lang/perl"
  15
  16 PATCHES=(
  17         "${FILESDIR}/unescaped-left-brace.patch"
  18         "${FILESDIR}/redundant-argument-to-sprintf.patch"
  19         "${FILESDIR}/ignore-amavis-startup-notifications.patch"
  20         "${FILESDIR}/ignore-utf8smtp-lines.patch"
  21         "${FILESDIR}/unchecked-encrypted.patch"
  22         "${FILESDIR}/file-libmagic-errors.patch"
  23 )
  24
  25 src_prepare() {
  26         default
  27         # Replace the default config file location with ours.
  28         local cfg_default='/usr/local/etc/${progname_prefix}-logwatch.conf'
  29         local cfg_gentoo='/etc/${progname_prefix}-logwatch.conf';
  30         sed -i "s~${cfg_default}~${cfg_gentoo}~" ${PN} \
  31                 || die 'failed to update the default config location'
  32 }
  33
  34 src_compile() {
  35         # The default make target just outputs instructions. We don't want
  36         # the user to see these, so we avoid the default emake.
  37         :
  38 }
  39
  40 src_install() {
  41         dodoc Bugs Changes README
  42         doman ${PN}.1
  43         dobin ${PN}
  44         insinto /etc
  45         doins ${PN}.conf
  46 }