net-libs/telepathy-glib/telepathy-glib-0.24.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 VALA_MIN_API_VERSION="0.18"
   8 VALA_USE_DEPEND="vapigen"
   9
  10 inherit gnome2 python-any-r1 vala virtualx
  11
  12 DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol"
  13 HOMEPAGE="https://telepathy.freedesktop.org/"
  14 SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
  15
  16 LICENSE="LGPL-2.1+"
  17 SLOT="0"
  18 KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
  19
  20 IUSE="debug +introspection +vala"
  21 REQUIRED_USE="vala? ( introspection )"
  22
  23 # Broken for a long time and upstream doesn't care
  24 # https://bugs.freedesktop.org/show_bug.cgi?id=63212
  25 RESTRICT="test"
  26
  27 RDEPEND="
  28         >=dev-libs/glib-2.36:2
  29         >=dev-libs/dbus-glib-0.90
  30         introspection? ( >=dev-libs/gobject-introspection-1.30 )
  31 "
  32 DEPEND="${RDEPEND}
  33         ${PYTHON_DEPS}
  34         dev-libs/libxslt
  35         dev-util/glib-utils
  36         dev-util/gtk-doc-am
  37         virtual/pkgconfig
  38         vala? ( $(vala_depend) )
  39 "
  40 # See bug 504744 for reference
  41 PDEPEND="
  42         net-im/telepathy-mission-control
  43 "
  44
  45 src_prepare() {
  46         use vala && vala_src_prepare
  47         gnome2_src_prepare
  48 }
  49
  50 src_configure() {
  51         gnome2_src_configure \
  52                 --disable-static \
  53                 --disable-installed-tests \
  54                 $(use_enable debug backtrace) \
  55                 $(use_enable debug debug-cache) \
  56                 $(use_enable introspection) \
  57                 $(use_enable vala vala-bindings)
  58 }
  59
  60 src_test() {
  61         unset DBUS_SESSION_BUS_ADDRESS
  62         # Needs dbus for tests (auto-launched)
  63         virtx emake -j1 check
  64 }