net-libs/serf/serf-1.3.9.ebuild

   1 # Copyright 2008-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit eutils scons-utils toolchain-funcs flag-o-matic
   7
   8 DESCRIPTION="HTTP client library"
   9 HOMEPAGE="https://serf.apache.org/"
  10 SRC_URI="mirror://apache/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="Apache-2.0"
  13 SLOT="1"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
  15 IUSE="kerberos static-libs libressl"
  16 RESTRICT="test"
  17
  18 RDEPEND="dev-libs/apr:1=
  19         dev-libs/apr-util:1=
  20         !libressl? ( dev-libs/openssl:0= ) libressl? ( dev-libs/libressl:0= )
  21         sys-libs/zlib:0=
  22         kerberos? ( virtual/krb5 )"
  23 DEPEND="${RDEPEND}
  24         >=dev-util/scons-2.3.0"
  25
  26 src_prepare() {
  27         #epatch "${FILESDIR}/${PN}-1.3.2-disable_linking_against_unneeded_libraries.patch"
  28         #epatch "${FILESDIR}/${PN}-1.3.8-scons_variables.patch"
  29         #epatch "${FILESDIR}/${PN}-1.3.8-tests.patch"
  30         epatch "${FILESDIR}/${PN}-1.3.8-static-lib.patch"
  31         epatch "${FILESDIR}/${PN}-1.3.8-openssl.patch"
  32
  33         # https://code.google.com/p/serf/issues/detail?id=133
  34         sed -e "/env.Append(CCFLAGS=\['-O2'\])/d" -i SConstruct
  35
  36         # need limits.h for PATH_MAX (only when EXTENSIONS is enabled)
  37         [[ ${CHOST} == *-solaris* ]] && append-cppflags -D__EXTENSIONS__
  38 }
  39
  40 src_compile() {
  41         myesconsargs=(
  42                 PREFIX="${EPREFIX}/usr"
  43                 LIBDIR="${EPREFIX}/usr/$(get_libdir)"
  44                 # These config scripts are sent through a shell with an empty env
  45                 # which breaks the SYSROOT usage in them.  Set the vars inline to
  46                 # avoid that.
  47                 APR="SYSROOT='${SYSROOT}' ${SYSROOT}${EPREFIX}/usr/bin/apr-1-config"
  48                 APU="SYSROOT='${SYSROOT}' ${SYSROOT}${EPREFIX}/usr/bin/apu-1-config"
  49                 BUILD_STATIC=$(usex static-libs)
  50                 AR="$(tc-getAR)"
  51                 RANLIB="$(tc-getRANLIB)"
  52                 CC="$(tc-getCC)"
  53                 CPPFLAGS="${CPPFLAGS}"
  54                 CFLAGS="${CFLAGS}"
  55                 LINKFLAGS="${LDFLAGS}"
  56         )
  57
  58         if use kerberos; then
  59                 myesconsargs+=( GSSAPI="${SYSROOT}${EPREFIX}/usr/bin/krb5-config" )
  60         fi
  61
  62         escons
  63 }
  64
  65 src_test() {
  66         escons check
  67 }
  68
  69 src_install() {
  70         escons install --install-sandbox="${D}"
  71 }