net-libs/serf/serf-1.3.8.ebuild

   1 # Copyright 2008-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit eutils scons-utils toolchain-funcs
   7
   8 DESCRIPTION="HTTP client library"
   9 HOMEPAGE="https://serf.apache.org/"
  10 SRC_URI="mirror://apache/${PN}/${P}.tar.bz2"
  11
  12 LICENSE="Apache-2.0"
  13 SLOT="1"
  14 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  15 IUSE="kerberos"
  16 RESTRICT="test"
  17
  18 RDEPEND="dev-libs/apr:1=
  19         dev-libs/apr-util:1=
  20         dev-libs/openssl:0=
  21         sys-libs/zlib:0=
  22         kerberos? ( virtual/krb5 )"
  23 DEPEND="${RDEPEND}
  24         >=dev-util/scons-2.3.0"
  25
  26 src_prepare() {
  27         epatch "${FILESDIR}/${PN}-1.3.2-disable_linking_against_unneeded_libraries.patch"
  28         epatch "${FILESDIR}/${PN}-1.3.8-scons_variables.patch"
  29         epatch "${FILESDIR}/${PN}-1.3.8-tests.patch"
  30
  31         # https://code.google.com/p/serf/issues/detail?id=133
  32         sed -e "/env.Append(CCFLAGS=\['-O2'\])/d" -i SConstruct
  33 }
  34
  35 src_compile() {
  36         local myesconsargs=(
  37                 PREFIX="${EPREFIX}/usr"
  38                 LIBDIR="${EPREFIX}/usr/$(get_libdir)"
  39                 APR="${EPREFIX}/usr/bin/apr-1-config"
  40                 APU="${EPREFIX}/usr/bin/apu-1-config"
  41                 OPENSSL="${EPREFIX}/usr"
  42                 CC="$(tc-getCC)"
  43                 CPPFLAGS="${CPPFLAGS}"
  44                 CFLAGS="${CFLAGS}"
  45                 LINKFLAGS="${LDFLAGS}"
  46         )
  47
  48         if use kerberos; then
  49                 myesconsargs+=(GSSAPI="${EPREFIX}/usr/bin/krb5-config")
  50         fi
  51
  52         escons
  53 }
  54
  55 src_test() {
  56         escons check
  57 }
  58
  59 src_install() {
  60         escons install --install-sandbox="${D}"
  61 }