net-libs/libvncserver/libvncserver-0.9.11-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit autotools eutils multilib-minimal
   7
   8 MY_PN="LibVNCServer"
   9
  10 DESCRIPTION="library for creating vnc servers"
  11 HOMEPAGE="https://libvnc.github.io/"
  12 SRC_URI="https://github.com/LibVNC/${PN}/archive/${MY_PN}-${PV}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 # No sub slot wanted (yet), see #578958
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
  18 IUSE="+24bpp gcrypt gnutls ipv6 +jpeg libressl +png ssl static-libs systemd test +threads +zlib"
  19 REQUIRED_USE="!gnutls? ( ssl? ( threads ) )"
  20
  21 DEPEND="
  22         gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0=[${MULTILIB_USEDEP}] )
  23         gnutls? (
  24                 >=net-libs/gnutls-2.12.23-r6:0=[${MULTILIB_USEDEP}]
  25                 >=dev-libs/libgcrypt-1.5.3:0=[${MULTILIB_USEDEP}]
  26         )
  27         !gnutls? (
  28                 ssl? (
  29                         !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
  30                         libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
  31                 )
  32         )
  33         jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
  34         png? ( >=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}] )
  35         systemd? ( sys-apps/systemd:= )
  36         zlib? ( >=sys-libs/zlib-1.2.8-r1:0=[${MULTILIB_USEDEP}] )"
  37 RDEPEND="${DEPEND}"
  38
  39 S="${WORKDIR}/${PN}-${MY_PN}-${PV}"
  40
  41 DOCS=( AUTHORS ChangeLog NEWS README TODO )
  42
  43 src_prepare() {
  44         default
  45
  46         sed -i -r \
  47                 -e "/^SUBDIRS/s:\<$(usex test '' 'test|')client_examples|examples\>::g" \
  48                 Makefile.am || die
  49
  50         eautoreconf
  51 }
  52
  53 multilib_src_configure() {
  54         ECONF_SOURCE=${S} \
  55         econf \
  56                 --disable-silent-rules \
  57                 $(use_enable static-libs static) \
  58                 $(use_with 24bpp) \
  59                 $(use_with gnutls) \
  60                 $(usex gnutls --with-gcrypt $(use_with gcrypt)) \
  61                 $(usex gnutls --without-ssl $(use_with ssl)) \
  62                 $(use_with ipv6) \
  63                 $(use_with jpeg) \
  64                 $(use_with png) \
  65                 $(use_with threads pthread) \
  66                 $(use_with zlib)
  67 }
  68
  69 multilib_src_install_all() {
  70         einstalldocs
  71         prune_libtool_files
  72 }