net-libs/libtrace/libtrace-4.0.11_p1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit autotools
   6
   7 DESCRIPTION="A library and tools for trace processing"
   8 HOMEPAGE="https://research.wand.net.nz/software/libtrace.php"
   9 SRC_URI="https://github.com/${PN^}Team/${PN}/archive//${PV/_p/-}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="LGPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="doc ncurses numa static-libs"
  15
  16 RDEPEND="
  17         >=net-libs/libpcap-0.8
  18         dev-libs/libyaml
  19         dev-libs/openssl:0=
  20         net-libs/wandio
  21         ncurses? ( sys-libs/ncurses:0= )
  22         numa? ( sys-process/numactl )
  23 "
  24 DEPEND="
  25         ${RDEPEND}
  26         app-doc/doxygen[dot]
  27         sys-devel/flex
  28         virtual/os-headers
  29         virtual/pkgconfig
  30         virtual/yacc
  31 "
  32 PATCHES=(
  33                 "${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
  34                 "${FILESDIR}"/${PN}-4.0.0-no-examples.patch
  35                 "${FILESDIR}"/${PN}-4.0.0-with-numa.patch
  36                 "${FILESDIR}"/${PN}-4.0.9_p1-tinfo.patch
  37 )
  38 S=${WORKDIR}/${P/_p/-}
  39
  40 src_prepare() {
  41         default
  42
  43         eautoreconf
  44
  45         # Comment out FILE_PATTERNS definition (bug #706230)
  46         if has_version ~app-doc/doxygen-1.8.16; then
  47                 sed -i -e '/^FILE_PATTERNS/s|^|#|g' docs/${PN}.doxygen.in || die
  48         fi
  49         # Update doxygen configuration
  50         doxygen -u docs/libtrace.doxygen.in || die
  51 }
  52
  53 src_configure() {
  54         econf \
  55                 $(use_enable static-libs static) \
  56                 $(use_with ncurses) \
  57                 $(use_with numa) \
  58                 --with-man
  59 }
  60
  61 src_install() {
  62         default
  63
  64         use doc && dodoc -r docs/doxygen/html
  65
  66         find "${D}" -name "*.la" -delete || die
  67 }