net-libs/libsoup/libsoup-2.66.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit gnome.org meson multilib-minimal vala xdg
   8
   9 DESCRIPTION="HTTP client/server library for GNOME"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="2.4"
  14
  15 IUSE="gssapi gtk-doc +introspection samba ssl test +vala"
  16 RESTRICT="!test? ( test )"
  17 REQUIRED_USE="vala? ( introspection )"
  18
  19 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 s390 sparc x86"
  20
  21 DEPEND="
  22         >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}]
  23         >=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
  24         >=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
  25         >=net-libs/libpsl-0.20[${MULTILIB_USEDEP}]
  26         gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
  27         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  28         samba? ( net-fs/samba )
  29 "
  30 RDEPEND="${DEPEND}
  31         >=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
  32 "
  33 BDEPEND="
  34         dev-util/glib-utils
  35         gtk-doc? ( >=dev-util/gtk-doc-1.20
  36                 app-text/docbook-xml-dtd:4.1.2 )
  37         >=sys-devel/gettext-0.19.8
  38         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  39         vala? ( $(vala_depend) )
  40 "
  41 #       test? ( www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
  42 #               apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
  43 #               apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
  44 #               dev-lang/php[apache2,xmlrpc]
  45 #               net-misc/curl
  46 #               net-libs/glib-networking[ssl])"
  47
  48 PATCHES=(
  49         # Disable apache tests until they are usable on Gentoo, bug #326957
  50         "${FILESDIR}"/disable-apache-tests.patch
  51         # Fix libsoup-2.4.vapi to be compatible with vala:0.46 and onwards. Included in 2.67.2
  52         "${FILESDIR}"/2.66.2-vala-0.46-compat.patch
  53         "${FILESDIR}"/2.66.2-meson-ntlm_auth-fix.patch
  54 )
  55
  56 src_prepare() {
  57         use vala && vala_src_prepare
  58         xdg_src_prepare
  59 }
  60
  61 src_configure() {
  62         # FIXME: we need addpredict to workaround bug #324779 until
  63         # root cause (bug #249496) is solved
  64         # But necessary while apache tests are disabled
  65         #addpredict /usr/share/snmp/mibs/.index
  66
  67         multilib-minimal_src_configure
  68 }
  69
  70 multilib_src_configure() {
  71         local emesonargs=(
  72                 $(meson_use gssapi)
  73                 -Dkrb5_config="${CHOST}-krb5-config"
  74                 $(meson_use samba ntlm)
  75                 -Dntlm_auth="${EPREFIX}/usr/bin/ntlm_auth"
  76                 -Dtls_check=false # disables check, we still rdep on glib-networking
  77                 -Dgnome=false
  78                 -Dintrospection=$(multilib_native_usex introspection true false)
  79                 -Dvapi=$(multilib_native_usex vala true false)
  80                 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
  81                 $(meson_use test tests)
  82         )
  83         meson_src_configure
  84 }
  85
  86 multilib_src_compile() {
  87         meson_src_compile
  88 }
  89
  90 multilib_src_test() {
  91         meson_src_test
  92 }
  93
  94 multilib_src_install() {
  95         meson_src_install
  96 }