net-libs/libsoup/libsoup-2.62.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python{3_5,3_6} )
   7 VALA_USE_DEPEND="vapigen"
   8
   9 inherit gnome2 multilib-minimal python-any-r1 vala
  10
  11 DESCRIPTION="An HTTP library implementation in C"
  12 HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
  13
  14 LICENSE="LGPL-2+"
  15 SLOT="2.4"
  16
  17 IUSE="debug gssapi +introspection samba ssl test +vala"
  18 REQUIRED_USE="vala? ( introspection )"
  19
  20 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21
  22 RDEPEND="
  23         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  24         >=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
  25         >=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
  26         >=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
  27         gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
  28         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  29         samba? ( net-fs/samba )
  30 "
  31 DEPEND="${RDEPEND}
  32         ${PYTHON_DEPS}
  33         dev-util/glib-utils
  34         >=dev-util/gtk-doc-am-1.20
  35         >=dev-util/intltool-0.35
  36         sys-devel/gettext
  37         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  38         test? ( >=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}] )
  39         vala? ( $(vala_depend) )
  40 "
  41 #       test? ( www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
  42 #               apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
  43 #               apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
  44 #               dev-lang/php[apache2,xmlrpc]
  45 #               net-misc/curl
  46 #               net-libs/glib-networking[ssl])"
  47
  48 src_prepare() {
  49         if ! use test; then
  50                 # don't waste time building tests (bug #226271)
  51                 sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  52                         || die "sed failed"
  53         fi
  54
  55         # FIXME: workaround upstream not respecting --without-apache-httpd
  56         sed -e '/check: start-httpd/d' \
  57                 -i tests/Makefile.am tests/Makefile.in || die
  58
  59         use vala && vala_src_prepare
  60         gnome2_src_prepare
  61 }
  62
  63 src_configure() {
  64         # FIXME: we need addpredict to workaround bug #324779 until
  65         # root cause (bug #249496) is solved
  66         addpredict /usr/share/snmp/mibs/.index
  67
  68         multilib-minimal_src_configure
  69 }
  70
  71 multilib_src_configure() {
  72         # Disable apache tests until they are usable on Gentoo, bug #326957
  73         ECONF_SOURCE=${S} \
  74         gnome2_src_configure \
  75                 --disable-static \
  76                 --disable-tls-check \
  77                 --without-gnome \
  78                 --without-apache-httpd \
  79                 $(usex debug --enable-debug=yes ' ') \
  80                 $(multilib_native_use_with gssapi) \
  81                 $(multilib_native_use_enable introspection) \
  82                 $(multilib_native_use_enable vala) \
  83                 $(use_with samba ntlm-auth '${EPREFIX}'/usr/bin/ntlm_auth)
  84
  85         if multilib_is_native_abi; then
  86                 # fix gtk-doc
  87                 ln -s "${S}"/docs/reference/html docs/reference/html || die
  88         fi
  89 }
  90
  91 multilib_src_install() {
  92         gnome2_src_install
  93 }