net-libs/libsoup/libsoup-2.56.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
   7 VALA_USE_DEPEND="vapigen"
   8
   9 inherit gnome2 multilib-minimal python-any-r1 vala
  10
  11 DESCRIPTION="An HTTP library implementation in C"
  12 HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
  13
  14 LICENSE="LGPL-2+"
  15 SLOT="2.4"
  16
  17 IUSE="debug gssapi +introspection samba ssl test vala"
  18 REQUIRED_USE="vala? ( introspection )"
  19
  20 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
  21
  22 RDEPEND="
  23         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  24         >=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
  25         >=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
  26         >=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
  27         gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
  28         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  29         samba? ( net-fs/samba )
  30 "
  31 DEPEND="${RDEPEND}
  32         ${PYTHON_DEPS}
  33         >=dev-util/intltool-0.35
  34         >=dev-util/gtk-doc-am-1.20
  35         sys-devel/gettext
  36         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  37         test? ( >=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}] )
  38         vala? ( $(vala_depend) )
  39 "
  40 #       test? ( www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
  41 #               apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
  42 #               apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
  43 #               dev-lang/php[apache2,xmlrpc]
  44 #               net-misc/curl
  45 #               net-libs/glib-networking[ssl])"
  46
  47 src_prepare() {
  48         if ! use test; then
  49                 # don't waste time building tests (bug #226271)
  50                 sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  51                         || die "sed failed"
  52         fi
  53
  54         use vala && vala_src_prepare
  55         gnome2_src_prepare
  56 }
  57
  58 src_configure() {
  59         # FIXME: we need addpredict to workaround bug #324779 until
  60         # root cause (bug #249496) is solved
  61         addpredict /usr/share/snmp/mibs/.index
  62
  63         multilib-minimal_src_configure
  64 }
  65
  66 multilib_src_configure() {
  67         # Disable apache tests until they are usable on Gentoo, bug #326957
  68         ECONF_SOURCE=${S} \
  69         gnome2_src_configure \
  70                 --disable-static \
  71                 --disable-tls-check \
  72                 --without-gnome \
  73                 --without-apache-httpd \
  74                 $(usex debug --enable-debug=yes ' ') \
  75                 $(multilib_native_use_with gssapi) \
  76                 $(multilib_native_use_enable introspection) \
  77                 $(multilib_native_use_enable vala) \
  78                 $(use_with samba ntlm-auth '${EPREFIX}'/usr/bin/ntlm_auth)
  79
  80         if multilib_is_native_abi; then
  81                 # fix gtk-doc
  82                 ln -s "${S}"/docs/reference/html docs/reference/html || die
  83         fi
  84 }
  85
  86 multilib_src_install() {
  87         gnome2_src_install
  88 }