net-libs/libqmi/libqmi-1.16.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit multilib
   7 if [[ ${PV} == "9999" ]] ; then
   8         inherit git-r3 autotools
   9         EGIT_REPO_URI="https://anongit.freedesktop.org/git/libqmi.git"
  10 else
  11         KEYWORDS="~amd64 ~arm ~mips ~ppc ~x86"
  12         SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
  13 fi
  14
  15 DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol helper library"
  16 HOMEPAGE="https://cgit.freedesktop.org/libqmi/"
  17
  18 LICENSE="LGPL-2"
  19 SLOT="0/5.1"    # soname of libqmi-glib.so
  20 IUSE="doc +mbim static-libs"
  21
  22 RDEPEND=">=dev-libs/glib-2.32
  23         mbim? ( >=net-libs/libmbim-1.14.0 )"
  24 DEPEND="${RDEPEND}
  25         doc? ( dev-util/gtk-doc )
  26         virtual/pkgconfig"
  27 [[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214
  28
  29 src_prepare() {
  30         default
  31         [[ -e configure ]] || eautoreconf
  32 }
  33
  34 src_configure() {
  35         econf \
  36                 --disable-more-warnings \
  37                 $(use_enable mbim mbim-qmux) \
  38                 $(use_enable static{-libs,}) \
  39                 $(use_enable {,gtk-}doc)
  40 }
  41
  42 src_install() {
  43         default
  44         use static-libs || rm -f "${ED}/usr/$(get_libdir)/${PN}-glib.la"
  45 }