net-libs/libisds/libisds-9999.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 [[ ${PV} = 9999* ]] && inherit git-r3 autotools
   7
   8 DESCRIPTION="Client library for accessing ISDS Soap services"
   9 HOMEPAGE="http://xpisar.wz.cz/libisds/"
  10 if [[ ${PV} = 9999* ]]; then
  11         EGIT_REPO_URI="git://repo.or.cz/${PN}.git"
  12 else
  13         SRC_URI="http://xpisar.wz.cz/${PN}/dist/${P}.tar.xz"
  14         KEYWORDS="~amd64 ~mips ~x86"
  15 fi
  16
  17 LICENSE="LGPL-3"
  18 SLOT="0"
  19 IUSE="+curl debug nls static-libs test"
  20
  21 COMMON_DEPEND="
  22         app-crypt/gpgme
  23         dev-libs/expat
  24         dev-libs/libgcrypt:0=
  25         dev-libs/libxml2
  26         curl? ( net-misc/curl[ssl] )
  27 "
  28 DEPEND="${COMMON_DEPEND}
  29         virtual/pkgconfig
  30         nls? ( sys-devel/gettext )
  31 "
  32 RDEPEND="${COMMON_DEPEND}
  33         >=app-crypt/gnupg-2
  34 "
  35
  36 DOCS=( NEWS README AUTHORS ChangeLog )
  37
  38 src_prepare() {
  39         default
  40         [[ ${PV} = 9999* ]] && eautoreconf
  41 }
  42
  43 src_configure() {
  44         local myeconfargs=(
  45                 --disable-fatalwarnings
  46                 $(use_with curl libcurl)
  47                 $(use_enable curl curlreauthorizationbug)
  48                 $(use_enable debug)
  49                 $(use_enable nls)
  50                 $(use_enable static-libs static)
  51                 $(use_enable test)
  52         )
  53         econf "${myeconfargs[@]}"
  54 }
  55
  56 src_install() {
  57         default
  58
  59         find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
  60 }